blob: 4000a01661366c96f0a35516dd5b281939021039 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit meson-multilib xdg
DESCRIPTION="An implementation of the Interactice Connectivity Establishment standard (ICE)"
HOMEPAGE="https://libnice.freedesktop.org/"
SRC_URI="https://libnice.freedesktop.org/releases/${P}.tar.gz"
LICENSE="|| ( MPL-1.1 LGPL-2.1 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
IUSE="+gnutls gtk-doc +introspection test +upnp"
RESTRICT="!test? ( test )"
RDEPEND="
>=dev-libs/glib-2.54:2[${MULTILIB_USEDEP}]
introspection? ( >=dev-libs/gobject-introspection-1.30.0:= )
gnutls? ( >=net-libs/gnutls-2.12.0:0=[${MULTILIB_USEDEP}] )
!gnutls? (
dev-libs/openssl:0=[${MULTILIB_USEDEP}] )
upnp? ( >=net-libs/gupnp-igd-0.2.4:0=[${MULTILIB_USEDEP}] )
"
DEPEND="${RDEPEND}"
BDEPEND="
dev-util/glib-utils
virtual/pkgconfig
gtk-doc? ( dev-util/gtk-doc
app-text/docbook-xml-dtd:4.1.2 )
"
PATCHES=(
# bugs 877451, 889820
"${FILESDIR}/libnice-0.1.19-remove-graphviz-dependency.patch"
)
src_prepare() {
default
# Broken w/ network-sandbox on (bug #847844)
sed -i -e '/test-set-port-range/d' tests/meson.build || die
}
multilib_src_configure() {
# gstreamer plugin split off into media-plugins/gst-plugins-libnice
local emesonargs=(
-Dgstreamer=disabled
-Dcrypto-library=$(usex gnutls gnutls openssl)
$(meson_native_use_feature introspection)
$(meson_feature test tests)
$(meson_feature upnp gupnp)
$(meson_native_use_feature gtk-doc gtk_doc)
)
meson_src_configure
}
multilib_src_install_all() {
einstalldocs
}
|
GitWeb
