blob: b08a90d709c0911577471051cd6ce2ec534eb2f8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python2_7 )
PYTHON_REQ_USE="tk"
inherit python-single-r1 user systemd toolchain-funcs autotools
DESCRIPTION="the legendary remote-mail retrieval and forwarding utility"
HOMEPAGE="http://www.fetchmail.info/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz"
LICENSE="GPL-2 public-domain"
SLOT="0"
KEYWORDS="~alpha amd64 arm hppa ia64 ~mips ppc ppc64 s390 sh sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="ssl nls kerberos tk socks libressl"
REQUIRED_USE="tk? ( ${PYTHON_REQUIRED_USE} )"
RDEPEND="ssl? (
!libressl? ( >=dev-libs/openssl-0.9.6:= )
libressl? ( dev-libs/libressl:= )
)
kerberos? (
virtual/krb5
!libressl? ( >=dev-libs/openssl-0.9.6:= )
libressl? ( dev-libs/libressl:= )
)
nls? ( virtual/libintl )
!elibc_glibc? ( sys-libs/e2fsprogs-libs )
socks? ( net-proxy/dante )
tk? ( ${PYTHON_DEPS} )"
DEPEND="${RDEPEND}
app-arch/xz-utils
sys-devel/flex
nls? ( sys-devel/gettext )"
DOCS="FAQ FEATURES NEWS NOTES README README.NTLM README.SSL* TODO"
HTML_DOCS="*.html"
PATCHES=(
"${FILESDIR}"/${P}-python-optional.patch
"${FILESDIR}"/${P}-tests.patch
"${FILESDIR}"/${P}-libressl.patch
)
pkg_setup() {
enewgroup ${PN}
enewuser ${PN} -1 -1 /var/lib/${PN} ${PN}
use tk && python-single-r1_pkg_setup
}
src_prepare() {
default
# don't compile during src_install
use tk && : > "${S}"/py-compile
eautoreconf
}
src_configure() {
use tk || export PYTHON=:
econf \
--enable-RPA \
--enable-NTLM \
--enable-SDPS \
$(use_enable nls) \
$(use_with ssl ssl "${EPREFIX}/usr") \
$(use kerberos && echo "--with-ssl=${EPREFIX}/usr") \
$(use_with kerberos gssapi) \
$(use_with kerberos kerberos5) \
--without-hesiod \
$(use_with socks)
}
src_compile() {
emake AR="$(tc-getAR)"
}
src_install() {
# fetchmail's homedir (holds fetchmail's .fetchids)
keepdir /var/lib/${PN}
fowners ${PN}:${PN} /var/lib/${PN}
fperms 700 /var/lib/${PN}
default
newinitd "${FILESDIR}"/fetchmail.initd fetchmail
newconfd "${FILESDIR}"/fetchmail.confd fetchmail
systemd_dounit "${FILESDIR}"/${PN}.service
systemd_newunit "${FILESDIR}"/${PN}_at.service "${PN}@.service"
systemd_dotmpfilesd "${FILESDIR}"/${PN}.conf
docinto contrib
local f
for f in contrib/* ; do
[ -f "${f}" ] && dodoc "${f}"
done
use tk && python_optimize
}
pkg_postinst() {
if [[ -z ${REPLACING_VERSIONS} ]]; then
elog "Please see /etc/conf.d/fetchmail if you want to adjust"
elog "the polling delay used by the fetchmail init script."
fi
}
|
GitWeb