blob: 3625148b6cb5b464832b8078c6d5be3b9e6f6843 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake optfeature xdg
DESCRIPTION="Simple (yet powerful) news feed reader"
HOMEPAGE="https://github.com/martinrotter/rssguard/"
SRC_URI="
https://github.com/martinrotter/rssguard/archive/${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="|| ( LGPL-3 GPL-2+ ) AGPL-3+ BSD GPL-3+ MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE="libmpv mysql qt6 qtmultimedia +sqlite webengine"
REQUIRED_USE="
|| ( mysql sqlite )
?? ( libmpv qtmultimedia )
"
BDEPEND="
!qt6? ( dev-qt/linguist-tools:5 )
qt6? ( dev-qt/qttools:6[linguist] )
"
DEPEND="
sys-libs/zlib:=
libmpv? ( media-video/mpv:= )
!qt6? (
dev-qt/qtconcurrent:5
dev-qt/qtcore:5
dev-qt/qtdbus:5
dev-qt/qtdeclarative:5
dev-qt/qtgui:5
dev-qt/qtmultimedia:5[gstreamer]
dev-qt/qtnetwork:5[ssl]
dev-qt/qtsql:5[mysql?,sqlite?]
dev-qt/qtwidgets:5
dev-qt/qtxml:5
libmpv? (
dev-qt/qtopengl:5
)
qtmultimedia? (
dev-qt/qtmultimedia:5
dev-qt/qtopengl:5
)
webengine? ( dev-qt/qtwebengine:5[widgets(+)] )
)
qt6? (
dev-qt/qtbase:6[concurrent,dbus,gui,mysql?,network,sql,sqlite?,ssl,widgets]
dev-qt/qtdeclarative:6
dev-qt/qtmultimedia:6[gstreamer]
dev-qt/qt5compat:6
media-libs/libglvnd
libmpv? (
dev-qt/qtbase:6[opengl]
)
qtmultimedia? (
dev-qt/qtbase:6[opengl]
dev-qt/qtmultimedia:6
)
webengine? ( dev-qt/qtwebengine:6[widgets(+)] )
)
"
RDEPEND="${DEPEND}"
src_configure() {
local mycmakeargs=(
-DBUILD_WITH_QT6=$(usex qt6)
-DNO_LITE=$(usex webengine)
-DREVISION_FROM_GIT=OFF
-DNO_UPDATE_CHECK=ON
-DENABLE_COMPRESSED_SITEMAP=ON
-DENABLE_MEDIAPLAYER_QTMULTIMEDIA=$(usex qtmultimedia)
-DENABLE_MEDIAPLAYER_LIBMPV=$(usex libmpv)
# recommended
-DMEDIAPLAYER_FORCE_OPENGL=ON
)
cmake_src_configure
}
pkg_postinst() {
xdg_pkg_postinst
optfeature "ad blocking functionality" "net-libs/nodejs[npm]"
}
|
GitWeb