blob: 5de589b0f985eec4e07ffafb74e33a99e180c614 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit meson optfeature toolchain-funcs xdg
DESCRIPTION="A free astronomical image processing software"
HOMEPAGE="https://www.siril.org/"
if [[ ${PV} == "9999" ]]; then
inherit git-r3
EGIT_REPO_URI="https://gitlab.com/free-astro/${PN}.git"
else
SRC_URI="https://gitlab.com/free-astro/siril/-/archive/${PV/_/-}/${PN}-${PV/_/-}.tar.bz2"
KEYWORDS="amd64 x86"
S="${WORKDIR}/${PN}-${PV/_/-}"
fi
LICENSE="GPL-3+ Boost-1.0"
SLOT="0"
IUSE="curl ffmpeg heif jpeg openmp png raw tiff wcs"
DEPEND="
>=dev-libs/glib-2.56.0:2
>=dev-libs/json-glib-1.2.6
>=dev-libs/libconfig-1.4[cxx]
>=media-gfx/exiv2-0.25
media-libs/librtprocess:=
>=media-libs/opencv-4.4.0:=
sci-libs/cfitsio
sci-libs/fftw:3.0=
sci-libs/gsl:=
x11-libs/cairo
>=x11-libs/gtk+-3.20.0:3
curl? ( net-misc/curl )
ffmpeg? ( media-video/ffmpeg:= )
heif? ( media-libs/libheif )
jpeg? ( media-libs/libjpeg-turbo:= )
png? ( >=media-libs/libpng-1.6.0 )
raw? ( media-libs/libraw )
tiff? ( media-libs/tiff:= )
wcs? ( >=sci-astronomy/wcslib-7.7 )
"
RDEPEND="
${DEPEND}
"
BDEPEND="x11-base/xorg-proto"
PATCHES=(
"${FILESDIR}/${PN}-docfiles.patch"
"${FILESDIR}/${PN}-$(ver_cut 1-2)-dependencies.patch"
"${FILESDIR}/${PN}-$(ver_cut 1-2)-execinfo-r2.patch"
)
DOCS=( README.md NEWS ChangeLog AUTHORS )
pkg_pretend() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
}
pkg_setup() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
}
src_configure() {
local emesonargs=(
-Dffms2=false
-Dcriterion=false
$(meson_use ffmpeg)
$(meson_use heif libheif)
$(meson_use jpeg libjpeg)
$(meson_use openmp)
$(meson_use png libpng)
$(meson_use raw libraw)
$(meson_use tiff libtiff)
$(meson_use wcs wcslib)
$(usex curl -Denable-libcurl=yes -Denable-libcurl=no)
)
meson_src_configure
}
pkg_postinst() {
xdg_desktop_database_update
xdg_icon_cache_update
xdg_mimeinfo_database_update
optfeature "gnuplot support" sci-visualization/gnuplot
}
|
GitWeb