1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{7,8,9} )
PYTHON_REQ_USE="sqlite"
if [[ ${PV} = *9999 ]]; then
EGIT_REPO_URI="https://github.com/${PN}/${PN^^}.git"
inherit git-r3
else
SRC_URI="https://qgis.org/downloads/${P}.tar.bz2
examples? ( https://qgis.org/downloads/data/qgis_sample_data.tar.gz -> qgis_sample_data-2.8.14.tar.gz )"
KEYWORDS="~amd64 ~x86"
fi
inherit cmake desktop python-single-r1 qmake-utils xdg
DESCRIPTION="User friendly Geographic Information System"
HOMEPAGE="https://www.qgis.org/en/site/"
LICENSE="GPL-2+ GPL-3+"
SLOT="0"
IUSE="3d examples georeferencer grass hdf5 mapserver netcdf opencl oracle polar postgres python qml"
REQUIRED_USE="${PYTHON_REQUIRED_USE} mapserver? ( python )"
BDEPEND="${PYTHON_DEPS}
dev-qt/linguist-tools:5
sys-devel/bison
sys-devel/flex
"
COMMON_DEPEND="
>=app-crypt/qca-2.3.0:2[ssl]
>=dev-db/spatialite-4.2.0
dev-db/sqlite:3
dev-libs/expat
dev-libs/libzip:=
dev-libs/protobuf:=
dev-libs/qtkeychain:=
dev-qt/designer:5
dev-qt/qtconcurrent:5
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtnetwork:5[ssl]
dev-qt/qtpositioning:5
dev-qt/qtprintsupport:5
dev-qt/qtserialport:5
dev-qt/qtsql:5
dev-qt/qtsvg:5
dev-qt/qtwidgets:5
dev-qt/qtxml:5
media-gfx/exiv2:=
>=sci-libs/gdal-3.0.4:=[geos]
sci-libs/geos
sci-libs/libspatialindex:=
>=sci-libs/proj-6.3.1:=
sys-libs/zlib
>=x11-libs/qscintilla-2.10.3:=
>=x11-libs/qwt-6.1.3-r2:6=[svg]
3d? ( dev-qt/qt3d:5 )
georeferencer? ( sci-libs/gsl:= )
grass? ( =sci-geosciences/grass-7*:= )
hdf5? ( sci-libs/hdf5:= )
mapserver? ( dev-libs/fcgi )
netcdf? ( sci-libs/netcdf:= )
opencl? ( virtual/opencl )
oracle? (
dev-db/oracle-instantclient:=
sci-libs/gdal:=[oracle]
)
polar? ( >=x11-libs/qwtpolar-1.1.1-r2 )
postgres? ( dev-db/postgresql:= )
python? (
${PYTHON_DEPS}
$(python_gen_cond_dep '
dev-python/httplib2[${PYTHON_MULTI_USEDEP}]
dev-python/jinja[${PYTHON_MULTI_USEDEP}]
dev-python/markupsafe[${PYTHON_MULTI_USEDEP}]
dev-python/owslib[${PYTHON_MULTI_USEDEP}]
dev-python/pygments[${PYTHON_MULTI_USEDEP}]
dev-python/PyQt5[designer,gui,network,printsupport,sql,svg,${PYTHON_MULTI_USEDEP}]
dev-python/python-dateutil[${PYTHON_MULTI_USEDEP}]
dev-python/pytz[${PYTHON_MULTI_USEDEP}]
dev-python/pyyaml[${PYTHON_MULTI_USEDEP}]
>=dev-python/qscintilla-python-2.10.3[${PYTHON_MULTI_USEDEP}]
dev-python/requests[${PYTHON_MULTI_USEDEP}]
dev-python/sip:=[${PYTHON_MULTI_USEDEP}]
dev-python/six[${PYTHON_MULTI_USEDEP}]
>=sci-libs/gdal-2.2.3[python,${PYTHON_MULTI_USEDEP}]
postgres? ( dev-python/psycopg:2[${PYTHON_MULTI_USEDEP}] )
')
)
qml? ( dev-qt/qtdeclarative:5 )
"
DEPEND="${COMMON_DEPEND}
dev-qt/qttest:5
"
RDEPEND="${COMMON_DEPEND}
sci-geosciences/gpsbabel
"
# Disabling test suite because upstream disallow running from install path
RESTRICT="test"
PATCHES=(
# git master
"${FILESDIR}/${PN}-3.16.0-cmake-lib-suffix.patch"
# TODO upstream
"${FILESDIR}/${PN}-3.16.1-featuresummary.patch"
"${FILESDIR}/${PN}-3.16.1-default-qmldir.patch"
)
pkg_setup() {
python-single-r1_pkg_setup
}
src_prepare() {
cmake_src_prepare
sed -e "/QtWebKit.*.py/d" \
-i python/PyQt/CMakeLists.txt || die
}
src_configure() {
local mycmakeargs=(
-DQGIS_MANUAL_SUBDIR=share/man/
-DQGIS_LIB_SUBDIR=$(get_libdir)
-DQGIS_PLUGIN_SUBDIR=$(get_libdir)/qgis
-DQWT_INCLUDE_DIR=/usr/include/qwt6
-DQWT_LIBRARY=/usr/$(get_libdir)/libqwt6-qt5.so
-DPEDANTIC=OFF
-DUSE_CCACHE=OFF
-DWITH_ANALYSIS=ON
-DWITH_APIDOC=OFF
-DWITH_GUI=ON
-DWITH_INTERNAL_MDAL=ON # not packaged, bug 684538
-DWITH_QSPATIALITE=ON
-DENABLE_TESTS=OFF
-DWITH_3D=$(usex 3d)
-DWITH_GEOREFERENCER=$(usex georeferencer)
-DWITH_GRASS7=$(usex grass)
$(cmake_use_find_package hdf5 HDF5)
-DWITH_SERVER=$(usex mapserver)
$(cmake_use_find_package netcdf NetCDF)
-DUSE_OPENCL=$(usex opencl)
-DWITH_ORACLE=$(usex oracle)
-DWITH_QWTPOLAR=$(usex polar)
-DWITH_POSTGRESQL=$(usex postgres)
-DWITH_BINDINGS=$(usex python)
-DWITH_CUSTOM_WIDGETS=$(usex python)
-DWITH_QUICK=$(usex qml)
-DWITH_QTWEBKIT=OFF
)
if use grass; then
mycmakeargs+=(
-DGRASS_PREFIX7=/usr/$(get_libdir)/grass70
)
fi
use python && mycmakeargs+=( -DBINDINGS_GLOBAL_INSTALL=ON )
# bugs 612956, 648726
addpredict /dev/dri/renderD128
addpredict /dev/dri/renderD129
cmake_src_configure
}
src_install() {
cmake_src_install
insinto /usr/share/mime/packages
doins debian/qgis.xml
if use examples; then
docinto examples
dodoc -r "${WORKDIR}"/qgis_sample_data/.
docompress -x /usr/share/doc/${PF}/examples
fi
if use python; then
python_optimize
python_optimize "${ED}"/usr/share/qgis/python
fi
if use grass; then
python_fix_shebang "${ED}"/usr/share/qgis/grass/scripts
fi
}
pkg_postinst() {
if use postgres; then
elog "If you don't intend to use an external PostGIS server"
elog "you should install:"
elog " dev-db/postgis"
elif use python; then
elog "Support of PostgreSQL is disabled."
elog "But some installed python-plugins import the psycopg2 module."
elog "If you do not need these plugins just disable them"
elog "in the Plugins menu, else you need to set USE=\"postgres\""
fi
xdg_pkg_postinst
}
|
GitWeb