blob: eaa92ba89d8036d55f5f28926b1a187193bb0046 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit gnome2 optfeature virtualx
DESCRIPTION="Partition editor for graphically managing your disk partitions"
HOMEPAGE="https://gparted.org/ https://gitlab.gnome.org/GNOME/gparted/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
LICENSE="GPL-2+ FDL-1.2+"
SLOT="0"
KEYWORDS="amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
IUSE="kde policykit wayland"
DEPEND="
!policykit? (
kde? ( >=kde-plasma/kde-cli-tools-5.8.6-r1[kdesu] ) )
policykit? ( >=sys-auth/polkit-0.102 )
>=dev-cpp/glibmm-2.56.1:2
>=dev-cpp/gtkmm-3.24:3.0
>=dev-libs/glib-2.58.3-r1:2
>=sys-block/parted-3.2:=
>=dev-libs/libsigc++-2.10.1:2
"
RDEPEND="${DEPEND}
>=sys-apps/util-linux-2.33.2
wayland? ( x11-apps/xhost )
"
BDEPEND="
app-text/docbook-xml-dtd:4.1.2
>=dev-util/intltool-0.51.0-r2
dev-util/itstool
sys-devel/gettext
virtual/pkgconfig
"
PATCHES=(
"${FILESDIR}"/${PN}-1.3.1-musl-nullptr.patch
)
src_configure() {
gnome2_src_configure \
--enable-doc \
--enable-online-resize \
$(use_enable wayland xhost-root) \
GKSUPROG=kdesu \
ac_cv_prog_have_scrollkeeper_update=no
}
src_install() {
gnome2_src_install
local _ddir="${D}"/usr/share/applications
local _bdir="${D}"/usr/bin
if ! use policykit; then
if use kde; then
cp "${_ddir}"/gparted{,-kde}.desktop || die
cp "${_bdir}"/gparted{,-kde} || die
sed -i -e '/Exec/ s:gparted:gparted-kde:' "${_ddir}"/gparted-kde.desktop || die
echo 'OnlyShowIn=KDE;' >> "${_ddir}"/gparted-kde.desktop || die
fi
else
sed -i -e 's:kdesu::' "${_bdir}"/gparted || die
fi
mv "${ED}"/usr/share/{appdata,metainfo}
}
src_test() {
virtx emake check
}
pkg_postinst() {
gnome2_pkg_postinst
optfeature_header
optfeature "BTRFS support" sys-fs/btrfs-progs
optfeature "DMRAID support" sys-fs/dmraid sys-fs/multipath-tools
optfeature "Encrypted device / LUKS support" sys-fs/cryptsetup
optfeature "exFAT support" sys-fs/exfatprogs
optfeature "EXT2/EXT3/EXT4 support" sys-fs/e2fsprogs
optfeature "F2FS support" sys-fs/f2fs-tools
optfeature "FAT support" sys-fs/dosfstools sys-fs/mtools
optfeature "HFS support" sys-fs/diskdev_cmds sys-fs/hfsutils virtual/udev
optfeature "JFS support" sys-fs/jfsutils
optfeature "MDADM support" sys-fs/mdadm
optfeature "NTFS support" sys-fs/ntfs3g[ntfsprogs]
optfeature "Reiser4 support" sys-fs/reiser4progs
optfeature "ReiserFS support" sys-fs/reiserfsprogs
optfeature "UDF support" sys-fs/udftools
optfeature "XFS support" sys-fs/xfsprogs sys-fs/xfsdump
}
|
GitWeb