blob: ee72ddca48c64d454ae49a9161e7c17934d4078c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
EGIT_REPO_URI="https://gitlab.freedesktop.org/pixman/pixman.git"
if [[ ${PV} = 9999* ]]; then
GIT_ECLASS="git-r3"
fi
inherit ${GIT_ECLASS} flag-o-matic meson-multilib multiprocessing toolchain-funcs
DESCRIPTION="Low-level pixel manipulation routines"
HOMEPAGE="http://www.pixman.org/ https://gitlab.freedesktop.org/pixman/pixman/"
if [[ ${PV} = 9999* ]]; then
SRC_URI=""
else
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
SRC_URI="https://www.x.org/releases/individual/lib/${P}.tar.xz"
fi
LICENSE="MIT"
SLOT="0"
IUSE="cpu_flags_ppc_altivec cpu_flags_arm_iwmmxt cpu_flags_arm_iwmmxt2 cpu_flags_arm_neon loongson2f cpu_flags_x86_mmxext cpu_flags_x86_sse2 cpu_flags_x86_ssse3 static-libs test"
RESTRICT="!test? ( test )"
pkg_pretend() {
[[ ${MERGE_TYPE} != binary ]] && use test && tc-check-openmp
}
pkg_setup() {
[[ ${MERGE_TYPE} != binary ]] && use test && tc-check-openmp
}
multilib_src_configure() {
if use arm && tc-is-clang ; then
# See bug #768138 and https://gitlab.freedesktop.org/pixman/pixman/-/issues/46
append-cflags $(test-flags-CC -fno-integrated-as)
fi
local emesonargs=(
$(meson_feature cpu_flags_arm_iwmmxt iwmmxt)
$(meson_use cpu_flags_arm_iwmmxt2 iwmmxt2)
$(meson_feature cpu_flags_x86_mmxext mmx)
$(meson_feature cpu_flags_x86_sse2 sse2)
$(meson_feature cpu_flags_x86_ssse3 ssse3)
$(meson_feature cpu_flags_ppc_altivec vmx)
$(meson_feature cpu_flags_arm_neon neon)
$(meson_feature loongson2f loongson-mmi)
$(meson_feature test openmp) # only used in unit tests
-Ddefault_library=$(usex static-libs both shared)
-Dgtk=disabled
-Dlibpng=disabled
)
meson_src_configure
}
multilib_src_test() {
export OMP_NUM_THREADS=$(makeopts_jobs)
meson_src_test -t 100
}
|
GitWeb
