blob: a8602b9f9bb2763adf007454d924db3416289ad6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit savedconfig toolchain-funcs
DESCRIPTION="a generic, highly customizable, and efficient menu for the X Window System"
HOMEPAGE="https://tools.suckless.org/dmenu/"
SRC_URI="https://dl.suckless.org/tools/${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="amd64 ~arm arm64 ~hppa ppc ppc64 ~riscv x86"
IUSE="xinerama"
RDEPEND="
media-libs/fontconfig
x11-libs/libX11
x11-libs/libXft
xinerama? ( x11-libs/libXinerama )
"
DEPEND="${RDEPEND}
x11-base/xorg-proto
"
BDEPEND="virtual/pkgconfig"
PATCHES=(
"${FILESDIR}"/${PN}-4.9-gentoo.patch
)
src_prepare() {
default
sed -i \
-e 's|^ @| |g' \
-e '/^ echo/d' \
Makefile || die
restore_config config.h
}
src_compile() {
emake CC="$(tc-getCC)" \
"FREETYPEINC=$( $(tc-getPKG_CONFIG) --cflags x11 fontconfig xft 2>/dev/null )" \
"FREETYPELIBS=$( $(tc-getPKG_CONFIG) --libs x11 fontconfig xft 2>/dev/null )" \
"X11INC=$( $(tc-getPKG_CONFIG) --cflags x11 2>/dev/null )" \
"X11LIB=$( $(tc-getPKG_CONFIG) --libs x11 2>/dev/null )" \
"XINERAMAFLAGS=$(
usex xinerama "-DXINERAMA $(
$(tc-getPKG_CONFIG) --cflags xinerama 2>/dev/null
)" ''
)" \
"XINERAMALIBS=$(
usex xinerama "$( $(tc-getPKG_CONFIG) --libs xinerama 2>/dev/null)" ''
)"
}
src_install() {
emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
save_config config.h
}
|
GitWeb
