Version bump

Package-Manager: portage-2.1.7.10/cvs/Linux x86_64

3 files changed, 159 insertions, 2 deletions

diff --git a/app-emulation/qemu/ChangeLog b/app-emulation/qemu/ChangeLog
index 04f81e48b91d..d2e79182a135 100644
--- a/app-emulation/qemu/ChangeLog
+++ b/app-emulation/qemu/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-emulation/qemu
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu/ChangeLog,v 1.74 2009/11/23 00:20:33 lu_zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu/ChangeLog,v 1.75 2009/12/06 22:00:55 lu_zero Exp $
+
+*qemu-0.11.1 (06 Dec 2009)
+
+  06 Dec 2009; Luca Barbato <lu_zero@gentoo.org> +qemu-0.11.1.ebuild:
+  Version bump
 
   23 Nov 2009; Luca Barbato <lu_zero@gentoo.org> qemu-0.11.0.ebuild:
   fix bug #286012, thanks to Thomas Kister <leander256@gmail.com> for the
diff --git a/app-emulation/qemu/Manifest b/app-emulation/qemu/Manifest
index fc23fdf407dc..833c680f8ea1 100644
--- a/app-emulation/qemu/Manifest
+++ b/app-emulation/qemu/Manifest
@@ -7,6 +7,7 @@ DIST qemu-0.10.4.tar.gz 3749481 RMD160 13e1a55dc9031a4a003d2694169ff3ec0681d504
 DIST qemu-0.10.5.tar.gz 3662495 RMD160 02eec8d3160e80ba9d04e5112977c2242a306a65 SHA1 236de8714554d98beb97f3fb34985f709bf7d3be SHA256 d54f268f5545dd182d96c1b09e79af58efaf2e51695efd1331d560a552d657c1
 DIST qemu-0.10.6.tar.gz 3664559 RMD160 1321a10777d2e0c6b53887d0525a28cc1b36ec9b SHA1 9432738ba513e07c981097468945b2e3ad9cb81e SHA256 8725298d4fd937ae41d942d0dd4a22fc02561d8c57a9fdcdbfa56427915757c7
 DIST qemu-0.11.0.tar.gz 3925830 RMD160 a9fc4c3fc814067bf042669b51d46c49e7879630 SHA1 95f59ce1293743d9f213d6908029aa2cadfc0d34 SHA256 bc2a7e73b93400315102ca7b47cf5c6cd5b5bcd7486f609f0f0f6ffe693076f0
+DIST qemu-0.11.1.tar.gz 3830070 RMD160 4da00fa6c01d7ff6af0ee781bc9260da577ea7d3 SHA1 7b983cd18f44c6e7627532b662f010389d3bcdff SHA256 2ecd2fc0af2ce5d96067ae82cc98a08275c596de53fc929484bedee1d6e7893a
 EBUILD qemu-0.10.0.ebuild 523 RMD160 3ed38003b3d0f40e4ef5c878b6e179d82e8c7dc3 SHA1 feb4b6f73ad34b5e944bc322313a8e8366f52e63 SHA256 a8fd334edf8d63615a7e556a9d2acd12b91437c00287b2a887515f3d7a563056
 EBUILD qemu-0.10.1.ebuild 523 RMD160 f0bcfa00d5c1d8bb746f77e9e9d8f4a91862f632 SHA1 58e0e0cd1f90ab699fcc3f6f4f280c6515bd6397 SHA256 cb86803cd8fa2985373717c209b4f8bddd5f0ca3de32f3ecce84883468c8a946
 EBUILD qemu-0.10.3.ebuild 4703 RMD160 e852ff28e625bc8f768a188ae71d66dbb23979f0 SHA1 ed61fd6b4a21c8854f4a65e54757c1ed59787521 SHA256 833daa66b0f562fb6649c968ab1447d6b287330175ed7777610297061a71d494
@@ -14,7 +15,8 @@ EBUILD qemu-0.10.4.ebuild 4787 RMD160 0214208a4161cfa6e2d2d75a572379fc50d23dc1 S
 EBUILD qemu-0.10.5.ebuild 4872 RMD160 4f1a41ec6567564968baa7c8790f7232f866a511 SHA1 781f1f5f1eaba1d8f99e9877bc3d55cf3f806a93 SHA256 fbedf067e0ebb55ab457dd2b2c648b8a5255d3b863ef2ecdf8db74ffc19a0b1c
 EBUILD qemu-0.10.6.ebuild 4844 RMD160 a4d3eabaf2fd25cc6fa4f4f9dbbb7147fefe246c SHA1 128bd72d72901ab07d6fe1223f36df0e30edd5b6 SHA256 b4b63038dbf1a1894c64943d72f9fcca4f1d86eafbb2b274b45de652df62d85a
 EBUILD qemu-0.11.0.ebuild 4895 RMD160 9524e43fef968a3849737bb944eaff30dd17183d SHA1 ca475ab11b9ec015144c0280ac5f5bd928994a03 SHA256 10829e5169f7e603f13ebc66fbc5790170666d02a6c24361997631748c13e0f3
+EBUILD qemu-0.11.1.ebuild 4895 RMD160 514cdbccab8e71444b53937fba67266c3f7a70ce SHA1 1418cb7ce40d99f134a1434fc519a68e897642c9 SHA256 7901fa02aa057080e835ca43cbfc23348a5a15f65a26b38577c67ae77a69467d
 EBUILD qemu-0.9.0.ebuild 503 RMD160 e6261c120b646da7f2106984ab8a833da1eaa095 SHA1 c4ec2424d608d4b38f395dbfe8f761ba4fbab835 SHA256 baa5050753763d8c20384f22de5e70748b100c66b8aa8a54107917519d00db4c
 EBUILD qemu-0.9.1.ebuild 515 RMD160 51683f0657c0e4ac6fbfa403fa9b81f027c9a830 SHA1 87031abd8579289862a692d32845b131f4cb3e1b SHA256 cd2b063cf0f40a170abfcbe2593ae1a82e99e3262d321a5bfdf02b5b62eab1e9
-MISC ChangeLog 9777 RMD160 ca0cd0434dd1ac125baac084807ae566690fadcf SHA1 5aaf7fe10c1c9b254714b80fd68343070742bb5f SHA256 9cfec5d001e15b7d7059c39d3ba2465f9d25d11e638a252d8dfa8cc59d4b643e
+MISC ChangeLog 9891 RMD160 cc489263e8f694003e9f0dc848b7b112ebb742e9 SHA1 218e0afe3df055540efafd0e934a0e2203971789 SHA256 da8007d023fa687ab2f7e01725fcf4b15da336089a7af3fd1b6653c2dbfd7385
 MISC metadata.xml 882 RMD160 259583b24a6eec2cbcca323e754f677041d44d54 SHA1 690460cdb502fd47b51eb1d51938d1c7629f7918 SHA256 8584426258959783d4da117036fa1d773b91b8f90d6a3c1ee7d065446e3d91f8
diff --git a/app-emulation/qemu/qemu-0.11.1.ebuild b/app-emulation/qemu/qemu-0.11.1.ebuild
new file mode 100644
index 000000000000..e52875992f44
--- /dev/null
+++ b/app-emulation/qemu/qemu-0.11.1.ebuild
@@ -0,0 +1,150 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu/qemu-0.11.1.ebuild,v 1.1 2009/12/06 22:00:55 lu_zero Exp $
+
+EAPI="2"
+
+inherit eutils flag-o-matic toolchain-funcs linux-info
+
+DESCRIPTION="QEMU emulator and ABI wrapper"
+HOMEPAGE="http://www.qemu.org"
+SRC_URI="http://download.savannah.gnu.org/releases/qemu/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="alsa bluetooth esd gnutls ncurses pulseaudio sasl +sdl vde kqemu kvm"
+
+COMMON_TARGETS="i386 x86_64 arm cris m68k mips mipsel mips64 mips64el ppc ppc64 sh4 sh4eb sparc"
+
+IUSE_SOFTMMU_TARGETS="${COMMON_TARGETS} ppcemb"
+IUSE_USER_TARGETS="${COMMON_TARGETS} alpha armeb ppc64abi32 sparc64 sparc32plus"
+
+for target in ${IUSE_SOFTMMU_TARGETS}; do
+	IUSE="${IUSE} +qemu_softmmu_targets_${target}"
+done
+
+for target in ${IUSE_USER_TARGETS}; do
+	IUSE="${IUSE} +qemu_user_targets_${target}"
+done
+
+RDEPEND="!app-emulation/qemu-softmmu
+	!app-emulation/qemu-user
+	!<app-emulation/qemu-0.10.3
+	sys-libs/zlib
+	alsa? ( >=media-libs/alsa-lib-1.0.13 )
+	esd? ( media-sound/esound )
+	pulseaudio? ( media-sound/pulseaudio )
+	gnutls? ( net-libs/gnutls )
+	ncurses? ( sys-libs/ncurses )
+	sasl? ( dev-libs/cyrus-sasl )
+	sdl? ( >=media-libs/libsdl-1.2.11 )
+	vde? ( net-misc/vde )
+	kvm? ( >=sys-kernel/linux-headers-2.6.29 )
+	bluetooth? ( net-wireless/bluez )
+	kqemu? ( >=app-emulation/kqemu-1.4.0_pre1 )"
+#	fdt? ( sys-apps/dtc )
+
+DEPEND="${RDEPEND}
+		gnutls? ( dev-util/pkgconfig )
+		app-text/texi2html"
+
+src_prepare() {
+	# avoid fdt till an updated release appears
+	sed -i -e 's:fdt="yes":fdt="no":' configure
+	# prevent docs to get automatically installed
+	sed -i '/$(DESTDIR)$(docdir)/d' Makefile
+	# Alter target makefiles to accept CFLAGS set via flag-o
+	sed -i 's/^\(C\|OP_C\|HELPER_C\)FLAGS=/\1FLAGS+=/' \
+		Makefile Makefile.target tests/Makefile
+	[[ -x /sbin/paxctl ]] && \
+		sed -i 's/^VL_LDFLAGS=$/VL_LDFLAGS=-Wl,-z,execheap/' \
+			Makefile.target
+	# Append CFLAGS while linking
+	sed -i 's/$(LDFLAGS)/$(QEMU_CFLAGS) $(CFLAGS) $(LDFLAGS)/' rules.mak
+	epatch "${FILESDIR}/qemu-0.11.0-mips64-user-fix.patch"
+}
+
+src_configure() {
+	local mycc conf_opts audio_opts softmmu_targets user_targets target_list
+
+	for target in ${IUSE_SOFTMMU_TARGETS} ; do
+		use "qemu_softmmu_targets_${target}" && \
+			softmmu_targets="${softmmu_targets} ${target}-softmmu"
+	done
+
+	for target in ${IUSE_USER_TARGETS} ; do
+		use "qemu_user_targets_${target}" && \
+			user_targets="${user_targets} ${target}-linux-user"
+	done
+
+	conf_opts="--disable-darwin-user --disable-bsd-user --disable-strip"
+
+	if test ! -z "${softmmu_targets}" ; then
+		einfo "Building following softmmu targets: ${softmmu_targets}"
+		use gnutls || conf_opts="$conf_opts --disable-vnc-tls"
+		use ncurses || conf_opts="$conf_opts --disable-curses"
+		use sasl || conf_opts="$conf_opts --disable-vnc-sasl"
+		use sdl || conf_opts="$conf_opts --disable-sdl"
+		use vde || conf_opts="$conf_opts --disable-vde"
+		use bluetooth || conf_opts="$conf_opts --disable-bluez"
+		use kqemu || conf_opts="$conf_opts --disable-kqemu"
+		use kvm || conf_opts="$conf_opts --disable-kvm"
+
+		audio_opts="oss"
+		use alsa && audio_opts="alsa $audio_opts"
+		use esd && audio_opts="esd $audio_opts"
+		use pulseaudio && audio_opts="pa $audio_opts"
+		use sdl && audio_opts="sdl $audio_opts"
+	else
+		einfo "Disabling softmmu emulation (no softmmu targets specified)"
+		conf_opts="$conf_opts --disable-system --disable-vnc-tls \
+		--disable-curses --disable-sdl --disable-vde \
+		--disable-kqemu --disable-kvm"
+	fi
+
+	if test ! -z "${user_targets}" ; then
+		einfo "Building following user targets: ${user_targets}"
+		conf_opts="$conf_opts --enable-linux-user"
+	else
+		einfo "Disabling usermode emulation (no usermode targets specified)"
+		conf_opts="--disable-linux-user"
+	fi
+
+#	use fdt || conf_opts="$conf_opts --disable-fdt"
+
+	conf_opts="$conf_opts --prefix=/usr"
+
+	target_list="${softmmu_targets} ${user_targets}"
+
+	filter-flags -fPIE
+
+	./configure ${conf_opts} \
+		--audio-drv-list="$audio_opts" \
+		--cc=$(tc-getCC) --host-cc=$(tc-getCC) \
+		--target-list="${target_list}" \
+		|| die "configure failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "make install failed"
+
+	exeinto /etc/qemu
+	doexe \
+		"${FILESDIR}/qemu-ifup" \
+		"${FILESDIR}/qemu-ifdown" \
+		|| die "qemu interface scripts failed"
+
+	dodoc Changelog MAINTAINERS TODO pci-ids.txt || die
+	newdoc pc-bios/README README.pc-bios || die
+	dohtml qemu-doc.html qemu-tech.html || die
+}
+
+pkg_postinst() {
+	elog "You will need the Universal TUN/TAP driver compiled into your"
+	elog "kernel or loaded as a module to use the virtual network device"
+	elog "if using -net tap.  You will also need support for 802.1d"
+	elog "Ethernet Bridging and a configured bridge if using the provided"
+	elog "qemu-ifup script from /etc/qemu."
+	echo
+}