Version bump

Package-Manager: portage-2.1.9.25/cvs/Linux x86_64

4 files changed, 193 insertions, 2 deletions

diff --git a/dev-dotnet/ikvm-bin/ChangeLog b/dev-dotnet/ikvm-bin/ChangeLog
index 775ccdb8c2bf..87ae24e523dc 100644
--- a/dev-dotnet/ikvm-bin/ChangeLog
+++ b/dev-dotnet/ikvm-bin/ChangeLog
@@ -1,6 +1,29 @@
 # ChangeLog for dev-dotnet/ikvm-bin
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-dotnet/ikvm-bin/ChangeLog,v 1.13 2010/09/23 22:16:40 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-dotnet/ikvm-bin/ChangeLog,v 1.14 2010/12/06 14:12:01 pacho Exp $
+
+*ikvm-bin-0.44.0.6 (06 Dec 2010)
+
+  06 Dec 2010; Pacho Ramos <pacho@gentoo.org> +ikvm-bin-0.44.0.6.ebuild:
+  Version bump:
+  - Backported various build system improvements.
+  - Backported IKVM.Reflection ILGenerator exception table sorting bug fix
+  (when running on Mono).
+  - Backported Mono 2.8 mcs build workarounds.
+  - Backported support for boolean, byte, char and short non-final static field
+  constant attributes.
+  - Backported core assembly detection fix.
+  - Backported fix to make sure that ikvmc (and ikvmstub) can find assemblies
+  that are part of a multi assembly (shared class loader) group (if the 
+  assembly is in the same directory as the main assembly of the group).
+  - Backported fix for regression in stack trace printing of .NET (not
+  remapped) exceptions introduced in 0.44. The .NET stack trace should not be 
+  included in the message.
+  - Backported fix for ikvmc sometimes incorrectly handling
+  InternalsVisibleToAttributes in multi assembly builds.
+  - Backported fix for regression introduced with fault handlers. Exception
+  handlers inside fault handlers could be ignored.
+  - Backported fix for #3086040. Volatile stores require a memory barrier.
 
   23 Sep 2010; Markos Chandras <hwoarang@gentoo.org>
   ikvm-bin-0.42.0.6.ebuild:
diff --git a/dev-dotnet/ikvm-bin/ikvm-bin-0.44.0.6.ebuild b/dev-dotnet/ikvm-bin/ikvm-bin-0.44.0.6.ebuild
new file mode 100644
index 000000000000..a55a72d2efff
--- /dev/null
+++ b/dev-dotnet/ikvm-bin/ikvm-bin-0.44.0.6.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-dotnet/ikvm-bin/ikvm-bin-0.44.0.6.ebuild,v 1.1 2010/12/06 14:12:01 pacho Exp $
+
+inherit eutils mono multilib
+
+MY_P=${P/-bin/}
+MY_PN=${PN/-bin/}
+
+DESCRIPTION="Java VM for .NET"
+HOMEPAGE="http://www.ikvm.net/ http://weblog.ikvm.net/"
+SRC_URI="http://www.frijters.net/${MY_PN}bin-${PV}.zip"
+LICENSE="as-is"
+
+SLOT="0"
+S=${WORKDIR}/${MY_P}
+
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND=">=dev-lang/mono-1.1
+		!dev-dotnet/ikvm
+		app-arch/unzip"
+RDEPEND="${DEPEND}"
+
+src_install() {
+	insinto /usr/$(get_libdir)/${MY_PN}
+	doins bin/* || die "doins failed"
+
+	for exe in ikvm ikvmc ikvmstub;
+	do
+		make_wrapper ${exe} "mono /usr/$(get_libdir)/${MY_PN}/${exe}.exe" || die
+	done
+
+	dodir /usr/$(get_libdir)/pkgconfig
+	sed -e "s:@VERSION@:${PV}:" \
+		-e "s:@LIBDIR@:$(get_libdir):" \
+		"${FILESDIR}"/ikvm-0.36.0.5.pc.in > "${D}"/usr/$(get_libdir)/pkgconfig/${MY_PN}.pc \
+		|| die "sed failed"
+
+	for dll in bin/IKVM*.dll
+	do
+		gacutil -i ${dll} -root "${D}"/usr/$(get_libdir) \
+			-gacdir /usr/$(get_libdir) -package ${dll} || die
+	done
+}
diff --git a/dev-dotnet/ikvm/ChangeLog b/dev-dotnet/ikvm/ChangeLog
index d66cfd9c4de6..b7fc3eac23e8 100644
--- a/dev-dotnet/ikvm/ChangeLog
+++ b/dev-dotnet/ikvm/ChangeLog
@@ -1,6 +1,29 @@
 # ChangeLog for dev-dotnet/ikvm
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-dotnet/ikvm/ChangeLog,v 1.24 2010/09/12 17:16:05 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-dotnet/ikvm/ChangeLog,v 1.25 2010/12/06 14:09:34 pacho Exp $
+
+*ikvm-0.44.0.6 (06 Dec 2010)
+
+  06 Dec 2010; Pacho Ramos <pacho@gentoo.org> +ikvm-0.44.0.6.ebuild:
+  Version bump:
+  - Backported various build system improvements.
+  - Backported IKVM.Reflection ILGenerator exception table sorting bug fix
+  (when running on Mono).
+  - Backported Mono 2.8 mcs build workarounds.
+  - Backported support for boolean, byte, char and short non-final static field
+  constant attributes.
+  - Backported core assembly detection fix.
+  - Backported fix to make sure that ikvmc (and ikvmstub) can find assemblies
+  that are part of a multi assembly (shared class loader) group (if the 
+  assembly is in the same directory as the main assembly of the group).
+  - Backported fix for regression in stack trace printing of .NET (not
+  remapped) exceptions introduced in 0.44. The .NET stack trace should not be 
+  included in the message.
+  - Backported fix for ikvmc sometimes incorrectly handling
+  InternalsVisibleToAttributes in multi assembly builds.
+  - Backported fix for regression introduced with fault handlers. Exception
+  handlers inside fault handlers could be ignored.
+  - Backported fix for #3086040. Volatile stores require a memory barrier.
 
 *ikvm-0.44.0.5 (12 Sep 2010)
 
diff --git a/dev-dotnet/ikvm/ikvm-0.44.0.6.ebuild b/dev-dotnet/ikvm/ikvm-0.44.0.6.ebuild
new file mode 100644
index 000000000000..fceb77fe93bb
--- /dev/null
+++ b/dev-dotnet/ikvm/ikvm-0.44.0.6.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-dotnet/ikvm/ikvm-0.44.0.6.ebuild,v 1.1 2010/12/06 14:09:34 pacho Exp $
+
+EAPI=2
+
+inherit eutils mono multilib java-pkg-2
+
+DESCRIPTION="Java VM for .NET"
+HOMEPAGE="http://www.ikvm.net/ http://weblog.ikvm.net/"
+SRC_URI="http://www.frijters.net/openjdk6-b18-stripped.zip
+	http://www.frijters.net/${PN}src-${PV}.zip"
+LICENSE="as-is"
+
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+RDEPEND=">=dev-lang/mono-2
+	dev-libs/glib"
+DEPEND="${RDEPEND}
+	!dev-dotnet/ikvm-bin
+	>=dev-dotnet/nant-0.85
+	>=virtual/jdk-1.6
+	app-arch/unzip
+	dev-util/pkgconfig
+	app-arch/sharutils"
+
+src_prepare() {
+	# We cannot rely on Mono Crypto Service Provider as it doesn't work inside
+	# sandbox, we simply hard-code the path to a bundled key like Debian does.
+	epatch "${FILESDIR}"/${PN}-0.44.0.5-key.patch
+	uudecode < "${FILESDIR}"/mono.snk.uu || die
+
+	# Ensures that we use Mono's bundled copy of SharpZipLib instead of relying
+	# on ikvm-bin one
+	sed -i -e 's:../bin/ICSharpCode.SharpZipLib.dll:ICSharpCode.SharpZipLib.dll:' \
+		ikvmc/ikvmc.build ikvmstub/ikvmstub.build || die
+
+	sed -i -e 's:pkg-config --cflags:pkg-config --cflags --libs:' \
+		native/native.build || die
+
+	mkdir -p "${T}"/home/test
+}
+
+src_configure() {
+	:
+}
+
+src_compile() {
+	XDG_CONFIG_HOME="${T}/home/test" nant -t:mono-2.0 signed || die "ikvm build failed"
+}
+
+generate_pkgconfig() {
+	ebegin "Generating .pc file"
+	local dll LSTRING="Libs:"
+	dodir "/usr/$(get_libdir)/pkgconfig"
+	cat <<- EOF -> "${D}/usr/$(get_libdir)/pkgconfig/${PN}.pc"
+		prefix=/usr
+		exec_prefix=\${prefix}
+		libdir=\${prefix}/$(get_libdir)
+		Name: IKVM.NET
+		Description: An implementation of Java for Mono and the Microsoft .NET Framework.
+		Version: ${PV}
+	EOF
+	for dll in "${S}"/bin/IKVM.*.dll
+	do
+		LSTRING="${LSTRING} -r:"'${libdir}'"/mono/IKVM/${dll##*/}"
+	done
+	printf "${LSTRING}" >> "${D}/usr/$(get_libdir)/pkgconfig/${PN}.pc"
+	PKG_CONFIG_PATH="${D}/usr/$(get_libdir)/pkgconfig/" pkg-config --silence-errors --libs ikvm &> /dev/null
+	eend $?
+}
+
+src_install() {
+	local dll dllbase exe
+	insinto /usr/$(get_libdir)/${PN}
+	doins bin/*.exe bin/*.so || die
+
+	dodir /bin
+	for exe in bin/*.exe
+	do
+		exebase=${exe##*/}
+		ebegin "Generating wrapper for ${exebase} -> ${exebase%.exe}"
+		make_wrapper ${exebase%.exe} "mono /usr/$(get_libdir)/${PN}/${exebase}"
+		eend $? || die "Failed generating wrapper for ${exebase}"
+	done
+
+	generate_pkgconfig || die "generating .pc failed"
+
+	for dll in bin/IKVM.*.dll
+	do
+		dllbase=${dll##*/}
+		ebegin "Installing and registering ${dllbase}"
+		gacutil -i bin/${dllbase} -root "${D}"/usr/$(get_libdir) \
+			-gacdir /usr/$(get_libdir) -package IKVM &>/dev/null
+		eend $? || die "Failed installing ${dllbase}"
+	done
+}