Use correct types of pointers. Fix failure of test_zlib with zlib 1.2.4 (Python issue #8193).

Package-Manager: portage-HEAD/cvs/Linux x86_64

3 files changed, 305 insertions, 2 deletions

diff --git a/dev-lang/python/ChangeLog b/dev-lang/python/ChangeLog
index 585648d78bca..6631ea99d0c2 100644
--- a/dev-lang/python/ChangeLog
+++ b/dev-lang/python/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-lang/python
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/python/ChangeLog,v 1.463 2010/03/25 20:10:22 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/python/ChangeLog,v 1.464 2010/04/11 21:22:49 arfrever Exp $
+
+*python-3.1.2-r2 (11 Apr 2010)
+
+  11 Apr 2010; Arfrever Frehtes Taifersar Arahesis <arfrever@gentoo.org>
+  +python-3.1.2-r2.ebuild:
+  Use correct types of pointers. Fix failure of test_zlib with zlib 1.2.4
+  (Python issue #8193).
 
 *python-3.1.2-r1 (25 Mar 2010)
 
diff --git a/dev-lang/python/Manifest b/dev-lang/python/Manifest
index 5f6750adb53c..dce19f74ea7f 100644
--- a/dev-lang/python/Manifest
+++ b/dev-lang/python/Manifest
@@ -20,6 +20,7 @@ DIST python-gentoo-patches-2.6.5-r2.tar.bz2 15706 RMD160 b1605f3c3b0887c7e7fd46f
 DIST python-gentoo-patches-3.1.1-r4.tar.bz2 10200 RMD160 418852c54bf7169eb7bab078e78997e22799139e SHA1 0c063cd446a22833e267710f59351cb157098b21 SHA256 c065659242df3e921290ff044aee6f543c8b5cd2290db5bf668065cf97fcbbbe
 DIST python-gentoo-patches-3.1.2-r1.tar.bz2 11601 RMD160 af8150aa23097931c28a611631e917bbd8f23f4f SHA1 227f2b094189de3d8723b6c707445ad73819e7ff SHA256 4575b76e99dc420f95b51b1e7098522bea7e72fd894c73da2d710074ba72dce0
 DIST python-gentoo-patches-3.1.2-r2.tar.bz2 12239 RMD160 6fe97b9875edb8a940774bfe1f508bdbfa0d2a44 SHA1 65db74ee0462b6fad7216833baebbd82869eb42c SHA256 bf7c0fb6d5522169c9d0266554055e0b5260ab0dc216dbc5f2a63d1ba21f5fa9
+DIST python-gentoo-patches-3.1.2-r3.tar.bz2 12576 RMD160 69713fa35cbf84ad98a604e29d909a8aa0179c0e SHA1 01b15dbe60aef5f4fdce5d373338dfb2eb4833d7 SHA256 ea9b6446da6490c88ef24743e18e9033c44a72abb4e8390e31e3a6801b36a0a5
 EBUILD python-2.4.6.ebuild 8966 RMD160 d48e302f289834896434b38113d1d98e7c0a4dbd SHA1 08004c836e1fa10401689ae2455b3790503ae0fc SHA256 f26f980b2d3697e8842dd36ca06b44f7eba921bca06b2388d8621d95065fcfc2
 EBUILD python-2.5.4-r4.ebuild 9306 RMD160 c11c7d75f4298228e5f1164b7315fb8d00294833 SHA1 36bae88672be35eb877f9b3ad0b1fd5dbf491a48 SHA256 30c8f1f29d2af9565e9b97f1ec266bf1aff283018f882ee9dbfbe02e175e48a2
 EBUILD python-2.6.4-r1.ebuild 9559 RMD160 99a85580a38955be98e2217dc65cb48d84082080 SHA1 d9620d4205f605d38d4058416b93f997b4313578 SHA256 3b968bae7990af61dc74a1c98c60f60e0fd711a444bdfbfd43dfe165688e3fc2
@@ -28,6 +29,7 @@ EBUILD python-2.6.5-r1.ebuild 9231 RMD160 69a339bf15f769c0c0455e25827a498747274a
 EBUILD python-2.6.5.ebuild 9228 RMD160 47b7340932deac8dea68779629cb448d706b42e6 SHA1 0a71fb985750482e2caa8e6d11614fd59bdfb249 SHA256 6692689ef3ab26b449ed3ba43f8635c939e9e11802ed16bc9a7d5f0e38a4b3bf
 EBUILD python-3.1.1-r1.ebuild 9134 RMD160 7ff62378f1c80f92ec9ca3c8106558e2705a9987 SHA1 ddb6cfa8e905c24f85afc6efff5168187523443d SHA256 e5ab994e0a2fa74e8c801fe629773c81ec50ec2d6316eac1d899ee88c8ec71f1
 EBUILD python-3.1.2-r1.ebuild 8802 RMD160 efaacc0e401f5e8b53ce0315888a3fca35b51e68 SHA1 1a725ed73a70de4fc68821bbeba0eda87845b889 SHA256 c2fab3e279559b9fd2f00c745313973a16849e3ec771c33c48ce18e747c856cb
+EBUILD python-3.1.2-r2.ebuild 8802 RMD160 d66f3bec04cc5c2ed67112c85d47bee82ae0f3f9 SHA1 2815db9e7cdd51698b698aadd4612b47c25d54db SHA256 73166aed679d683f320d872fcd06bbabe56357953707616178e607620cc87dc7
 EBUILD python-3.1.2.ebuild 8799 RMD160 5e5979e2f91367805b87fc66819f1228d1b96c0c SHA1 71ca84ddb3ae055b95fffe10958a9073c1a062aa SHA256 586d1b9d6fe0b4d94139a657c2235d29788e4601079a97408c38b21df1c0ae51
-MISC ChangeLog 82210 RMD160 3b6233fc5bff8e33434fd4415da8cf474afa57b1 SHA1 d7de089fb01877a7ed40f23e7b89e327fddb1e64 SHA256 8379d15076ae02e366e88d07cc1c8695b3a50f2f2f71f6b0b0031a487de4ba54
+MISC ChangeLog 82441 RMD160 7d07c32616aefb8111a7b625b3600b327896d814 SHA1 e493f26b0763da6386e72c0052f6c88758153819 SHA256 f16496608efae178695f5eb7b70cc29d56f2cf882265cec45478708a7be134f8
 MISC metadata.xml 661 RMD160 54831d16b8807086bfabdbb3df9d33336b5d42a0 SHA1 9867c337fe9e6f4e967004fc9409763e0fedf43b SHA256 2c6c3407251f7ccd6501dee49494e539a9544f2fbae99a4373eefdf4e83e8908
diff --git a/dev-lang/python/python-3.1.2-r2.ebuild b/dev-lang/python/python-3.1.2-r2.ebuild
new file mode 100644
index 000000000000..d2710b56265d
--- /dev/null
+++ b/dev-lang/python/python-3.1.2-r2.ebuild
@@ -0,0 +1,294 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/python/python-3.1.2-r2.ebuild,v 1.1 2010/04/11 21:22:49 arfrever Exp $
+
+EAPI="2"
+
+inherit autotools eutils flag-o-matic multilib pax-utils python toolchain-funcs
+
+MY_P="Python-${PV}"
+S="${WORKDIR}/${MY_P}"
+
+PATCHSET_REVISION="3"
+
+DESCRIPTION="Python is an interpreted, interactive, object-oriented programming language."
+HOMEPAGE="http://www.python.org/"
+SRC_URI="http://www.python.org/ftp/python/${PV}/${MY_P}.tar.bz2
+	mirror://gentoo/python-gentoo-patches-${PV}$([[ "${PATCHSET_REVISION}" != "0" ]] && echo "-r${PATCHSET_REVISION}").tar.bz2"
+
+LICENSE="PSF-2.2"
+SLOT="3.1"
+PYTHON_ABI="${SLOT}"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+IUSE="build doc elibc_uclibc examples gdbm ipv6 +ncurses +readline sqlite +ssl +threads tk +wide-unicode wininst +xml"
+
+RDEPEND=">=app-admin/eselect-python-20091230
+		>=sys-libs/zlib-1.1.3
+		virtual/libffi
+		virtual/libintl
+		!build? (
+			doc? ( dev-python/python-docs:${SLOT} )
+			gdbm? ( sys-libs/gdbm )
+			ncurses? (
+				>=sys-libs/ncurses-5.2
+				readline? ( >=sys-libs/readline-4.1 )
+			)
+			sqlite? ( >=dev-db/sqlite-3 )
+			ssl? ( dev-libs/openssl )
+			tk? ( >=dev-lang/tk-8.0 )
+			xml? ( >=dev-libs/expat-2 )
+		)"
+DEPEND="${RDEPEND}
+		dev-util/pkgconfig
+		!sys-devel/gcc[libffi]"
+RDEPEND+=" !build? ( app-misc/mime-types )"
+PDEPEND=">=app-admin/python-updater-0.8
+		|| ( dev-lang/python:2.7 dev-lang/python:2.6 )"
+
+PROVIDE="virtual/python"
+
+src_prepare() {
+	# Ensure that internal copies of expat and libffi aren't used.
+	rm -fr Modules/expat
+	rm -fr Modules/_ctypes/libffi*
+
+	if ! tc-is-cross-compiler; then
+		rm "${WORKDIR}/${PV}"/*_all_crosscompile.patch
+	fi
+
+	EPATCH_SUFFIX="patch" epatch "${WORKDIR}/${PV}"
+
+	sed -i -e "s:@@GENTOO_LIBDIR@@:$(get_libdir):g" \
+		Lib/distutils/command/install.py \
+		Lib/distutils/sysconfig.py \
+		Lib/site.py \
+		Makefile.pre.in \
+		Modules/Setup.dist \
+		Modules/getpath.c \
+		setup.py || die "sed failed to replace @@GENTOO_LIBDIR@@"
+
+	# Fix os.utime() on hppa. utimes it not supported but unfortunately reported as working - gmsoft (22 May 04)
+	# PLEASE LEAVE THIS FIX FOR NEXT VERSIONS AS IT'S A CRITICAL FIX !!!
+	[[ "${ARCH}" == "hppa" ]] && sed -e "s/utimes //" -i "${S}/configure"
+
+	if ! use wininst; then
+		# Remove Microsoft Windows executables.
+		rm Lib/distutils/command/wininst-*.exe
+	fi
+
+	# Fix OtherFileTests.testStdin() not to assume
+	# that stdin is a tty for bug #248081.
+	sed -e "s:'osf1V5':'osf1V5' and sys.stdin.isatty():" -i Lib/test/test_file.py || die "sed failed"
+
+	eautoreconf
+}
+
+src_configure() {
+	# Disable extraneous modules with extra dependencies.
+	if use build; then
+		export PYTHON_DISABLE_MODULES="gdbm _curses _curses_panel readline _sqlite3 _tkinter _elementtree pyexpat"
+		export PYTHON_DISABLE_SSL="1"
+	else
+		local disable
+		use gdbm     || disable+=" gdbm"
+		use ncurses  || disable+=" _curses _curses_panel"
+		use readline || disable+=" readline"
+		use sqlite   || disable+=" _sqlite3"
+		use ssl      || export PYTHON_DISABLE_SSL="1"
+		use tk       || disable+=" _tkinter"
+		use xml      || disable+=" _elementtree pyexpat" # _elementtree uses pyexpat.
+		export PYTHON_DISABLE_MODULES="${disable}"
+
+		if ! use xml; then
+			ewarn "You have configured Python without XML support."
+			ewarn "This is NOT a recommended configuration as you"
+			ewarn "may face problems parsing any XML documents."
+		fi
+	fi
+
+	if [[ -n "${PYTHON_DISABLE_MODULES}" ]]; then
+		einfo "Disabled modules: ${PYTHON_DISABLE_MODULES}"
+	fi
+
+	if [[ "$(gcc-major-version)" -ge 4 ]]; then
+		append-flags -fwrapv
+	fi
+
+	filter-flags -malign-double
+
+	[[ "${ARCH}" == "alpha" ]] && append-flags -fPIC
+
+	# https://bugs.gentoo.org/show_bug.cgi?id=50309
+	if is-flag -O3; then
+		is-flag -fstack-protector-all && replace-flags -O3 -O2
+		use hardened && replace-flags -O3 -O2
+	fi
+
+	if tc-is-cross-compiler; then
+		OPT="-O1" CFLAGS="" LDFLAGS="" CC="" \
+		./configure --{build,host}=${CBUILD} || die "cross-configure failed"
+		emake python Parser/pgen || die "cross-make failed"
+		mv python hostpython
+		mv Parser/pgen Parser/hostpgen
+		make distclean
+		sed -i \
+			-e "/^HOSTPYTHON/s:=.*:=./hostpython:" \
+			-e "/^HOSTPGEN/s:=.*:=./Parser/hostpgen:" \
+			Makefile.pre.in || die "sed failed"
+	fi
+
+	# Export CXX so it ends up in /usr/lib/python3.X/config/Makefile.
+	tc-export CXX
+
+	# Set LDFLAGS so we link modules with -lpython3.1 correctly.
+	# Needed on FreeBSD unless Python 3.1 is already installed.
+	# Please query BSD team before removing this!
+	append-ldflags "-L."
+
+	local dbmliborder
+	if use gdbm; then
+		dbmliborder+="${dbmliborder:+:}gdbm"
+	fi
+
+	OPT="" econf \
+		--with-fpectl \
+		--enable-shared \
+		$(use_enable ipv6) \
+		$(use_with threads) \
+		$(use_with wide-unicode) \
+		--infodir='${prefix}/share/info' \
+		--mandir='${prefix}/share/man' \
+		--with-computed-gotos \
+		--with-dbmliborder="${dbmliborder}" \
+		--with-libc="" \
+		--with-system-ffi
+}
+
+src_compile() {
+	emake EXTRA_CFLAGS="${CFLAGS}" || die "emake failed"
+}
+
+src_test() {
+	# Tests won't work when cross compiling.
+	if tc-is-cross-compiler; then
+		elog "Disabling tests due to crosscompiling."
+		return
+	fi
+
+	# Byte compiling should be enabled here.
+	# Otherwise test_import fails.
+	python_enable_pyc
+
+	# Skip all tests that fail during emerge but pass without emerge:
+	# (See bug #67970)
+	local skip_tests="distutils"
+
+	# test_ctypes fails with PAX kernel (bug #234498).
+	host-is-pax && skip_tests+=" ctypes"
+
+	for test in ${skip_tests}; do
+		mv "${S}/Lib/test/test_${test}.py" "${T}"
+	done
+
+	# Rerun failed tests in verbose mode (regrtest -w).
+	EXTRATESTOPTS="-w" make test || die "make test failed"
+
+	for test in ${skip_tests}; do
+		mv "${T}/test_${test}.py" "${S}/Lib/test/test_${test}.py"
+	done
+
+	elog "The following tests have been skipped:"
+	for test in ${skip_tests}; do
+		elog "test_${test}.py"
+	done
+
+	elog "If you'd like to run them, you may:"
+	elog "cd $(python_get_libdir)/test"
+	elog "and run the tests separately."
+
+	python_disable_pyc
+}
+
+src_install() {
+	emake DESTDIR="${D}" altinstall || die "emake altinstall failed"
+
+	mv "${D}usr/bin/python${SLOT}-config" "${D}usr/bin/python-config-${SLOT}"
+
+	# Fix collisions between different slots of Python.
+	mv "${D}usr/bin/2to3" "${D}usr/bin/2to3-${SLOT}"
+	mv "${D}usr/bin/pydoc3" "${D}usr/bin/pydoc${SLOT}"
+	mv "${D}usr/bin/idle3" "${D}usr/bin/idle${SLOT}"
+	rm -f "${D}usr/bin/smtpd.py"
+
+	if use build; then
+		rm -fr "${D}usr/bin/idle${SLOT}" "${D}$(python_get_libdir)/"{idlelib,sqlite3,test,tkinter}
+	else
+		use elibc_uclibc && rm -fr "${D}$(python_get_libdir)/test"
+		use sqlite || rm -fr "${D}$(python_get_libdir)/"{sqlite3,test/test_sqlite*}
+		use tk || rm -fr "${D}usr/bin/idle${SLOT}" "${D}$(python_get_libdir)/"{idlelib,tkinter,test/test_tk*}
+	fi
+
+	use threads || rm -fr "${D}$(python_get_libdir)/multiprocessing"
+
+	prep_ml_includes $(python_get_includedir)
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins -r "${S}/Tools" || die "doins failed"
+	fi
+
+	newinitd "${FILESDIR}/pydoc.init" pydoc-${SLOT}
+	newconfd "${FILESDIR}/pydoc.conf" pydoc-${SLOT}
+}
+
+pkg_preinst() {
+	if has_version "<${CATEGORY}/${PN}-${SLOT}" && ! has_version ">=${CATEGORY}/${PN}-${SLOT}_alpha"; then
+		python_updater_warning="1"
+	fi
+}
+
+eselect_python_update() {
+	local eselect_python_options=
+	[[ "$(eselect python show)" == "python2."* ]] && eselect_python_options="--python2"
+
+	# Create python3 symlink.
+	eselect python update --python3 > /dev/null
+
+	eselect python update ${eselect_python_options}
+}
+
+pkg_postinst() {
+	eselect_python_update
+
+	python_mod_optimize -x "(site-packages|test)" $(python_get_libdir)
+
+	if [[ "$(eselect python show)" == "python2."* ]]; then
+		ewarn
+		ewarn "WARNING!"
+		ewarn "Many Python modules haven't been ported yet to Python 3.*."
+		ewarn "Python 3 hasn't been activated and Python wrapper is still configured to use Python 2."
+		ewarn "You can manually activate Python ${SLOT} using \`eselect python set python${SLOT}\`."
+		ewarn "It is recommended to currently have Python wrapper configured to use Python 2."
+		ewarn "Having Python wrapper configured to use Python 3 is unsupported."
+		ewarn
+		ebeep 6
+	fi
+
+	if [[ "${python_updater_warning}" == "1" ]]; then
+		ewarn
+		ewarn "\e[1;31m************************************************************************\e[0m"
+		ewarn
+		ewarn "You have just upgraded from an older version of Python."
+		ewarn "You should run 'python-updater \${options}' to rebuild Python modules."
+		ewarn
+		ewarn "\e[1;31m************************************************************************\e[0m"
+		ewarn
+		ebeep 12
+	fi
+}
+
+pkg_postrm() {
+	eselect_python_update
+
+	python_mod_cleanup $(python_get_libdir)
+}