[kde-base] KDE SC 4.7.2

Package-Manager: portage-2.2.0_alpha61/cvs/Linux x86_64

2 files changed, 82 insertions, 1 deletions

diff --git a/kde-base/korundum/ChangeLog b/kde-base/korundum/ChangeLog
index e75d6971c0e7..adb589708f14 100644
--- a/kde-base/korundum/ChangeLog
+++ b/kde-base/korundum/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/korundum
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/korundum/ChangeLog,v 1.88 2011/09/07 20:13:59 alexxy Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/korundum/ChangeLog,v 1.89 2011/10/06 18:10:53 alexxy Exp $
+
+*korundum-4.7.2 (06 Oct 2011)
+
+  06 Oct 2011; Alexey Shvetsov <alexxy@gentoo.org> +korundum-4.7.2.ebuild:
+  Version bump KDE SC 4.7.2
 
 *korundum-4.7.1 (07 Sep 2011)
 
diff --git a/kde-base/korundum/korundum-4.7.2.ebuild b/kde-base/korundum/korundum-4.7.2.ebuild
new file mode 100644
index 000000000000..b286becf899f
--- /dev/null
+++ b/kde-base/korundum/korundum-4.7.2.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/korundum/korundum-4.7.2.ebuild,v 1.1 2011/10/06 18:10:53 alexxy Exp $
+
+EAPI=4
+
+OPENGL_REQUIRED="always"
+KDE_SCM="git"
+
+USE_RUBY="ruby18"
+# No ruby19 for three reasons:
+# 1) it does not build (yet) - will likely be solved soon
+# 2) cmake bails when configuring twice or more - solved with CMAKE_IN_SOURCE_BUILD=1
+# 3) the ebuild can only be installed for one ruby variant, otherwise the compiled
+#    files with identical path+name will overwrite each other - difficult :(
+
+inherit kde4-base ruby-ng
+
+DESCRIPTION="KDE Ruby bindings"
+KEYWORDS="~amd64 ~x86"
+IUSE="akonadi debug kate okular semantic-desktop"
+
+DEPEND="
+	$(add_kdebase_dep qtruby)
+	$(add_kdebase_dep smokekde 'akonadi?,kate?,okular?,semantic-desktop=')
+	$(add_kdebase_dep smokeqt)
+"
+RDEPEND="${DEPEND}
+"
+
+# Split from kdebindings-ruby in 4.7
+add_blocker kdebindings-ruby
+
+pkg_setup() {
+	ruby-ng_pkg_setup
+	kde4-base_pkg_setup
+}
+
+src_unpack() {
+	local S="${WORKDIR}/${P}"
+	kde4-base_src_unpack
+
+	cd "${WORKDIR}"
+	mkdir all
+	mv ${P} all/ || die "Could not move sources"
+}
+
+all_ruby_prepare() {
+	kde4-base_src_prepare
+}
+
+each_ruby_configure() {
+	CMAKE_USE_DIR=${S}
+	mycmakeargs=(
+		-DRUBY_LIBRARY=$(ruby_get_libruby)
+		-DRUBY_INCLUDE_PATH=$(ruby_get_hdrdir)
+		-DRUBY_EXECUTABLE=${RUBY}
+		$(cmake-utils_use_with akonadi)
+		$(cmake-utils_use_with akonadi KdepimLibs)
+		$(cmake-utils_use_disable kate)
+		$(cmake-utils_use_with okular)
+		$(cmake-utils_use_with semantic-desktop Nepomuk)
+		$(cmake-utils_use_with semantic-desktop Soprano)
+	)
+	kde4-base_src_configure
+}
+
+each_ruby_compile() {
+	CMAKE_USE_DIR=${S}
+	kde4-base_src_compile
+}
+
+each_ruby_install() {
+	CMAKE_USE_DIR=${S}
+	kde4-base_src_install
+}