version bump

Package-Manager: portage-2.2.0_alpha84/cvs/Linux x86_64

3 files changed, 284 insertions, 5 deletions

diff --git a/media-video/ffmpeg/ChangeLog b/media-video/ffmpeg/ChangeLog
index 5c4e88ba48f7..d84544859167 100644
--- a/media-video/ffmpeg/ChangeLog
+++ b/media-video/ffmpeg/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/ffmpeg
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ChangeLog,v 1.522 2012/01/28 12:19:08 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ChangeLog,v 1.523 2012/01/28 12:50:55 aballier Exp $
+
+*ffmpeg-0.10 (28 Jan 2012)
+
+  28 Jan 2012; Alexis Ballier <aballier@gentoo.org> +ffmpeg-0.10.ebuild:
+  version bump
 
   28 Jan 2012; Alexis Ballier <aballier@gentoo.org> ffmpeg-9999.ebuild:
   avconv is gone in master
diff --git a/media-video/ffmpeg/Manifest b/media-video/ffmpeg/Manifest
index 4e138c3ed7ca..c69487f6e528 100644
--- a/media-video/ffmpeg/Manifest
+++ b/media-video/ffmpeg/Manifest
@@ -2,17 +2,19 @@
 Hash: SHA1
 
 AUX ffmpeg-0.7.6-fix_ppc64_32ul.patch 1094 RMD160 b765f1f8420701e6d9447391dd498f6807b2e2e7 SHA1 f4fd276e9a88d815657282d67b716dc793f30988 SHA256 b6e60ba7f9d179b8b2ba03cf74694d1e92e6fc6d4626cda258ab1af50e0afea4
+DIST ffmpeg-0.10.tar.bz2 5778962 RMD160 a60568d4e8bd1a44a2c986e0648cfacba766bcd4 SHA1 a3a7fe25db760a99d51266b33386da9c8552feef SHA256 43596aa76d1a0fab6d42927bf60383405de2bca8fbc740c2012877559ae17ff9
 DIST ffmpeg-0.7.8.tar.bz2 4530406 RMD160 8f69a6bc5caaba4e3d440c2d5dc96a946454a52c SHA1 df4983c028a61d4bf3baceab3bae535b91b8928a SHA256 548197968e69b732c12b2cad3173eb6933a9573a7b1f5b29be36d31b9977c9f3
 DIST ffmpeg-0.9.1.tar.bz2 4974636 RMD160 2fac1b2520418d9e1b2b821e46c94a650a8770f3 SHA1 89326f93902aee49dac659a63b39b0f69be0e7ee SHA256 f6df7f47d8b63aa14c5a9d64d72f61966b03631ebb6982e38802b9da128195ca
+EBUILD ffmpeg-0.10.ebuild 8266 RMD160 0d37d37026761bb44b2a1d38f199c9f975ee13e0 SHA1 39965c8e25c1110d82b03fed3ef0e741dfc117f9 SHA256 48470018842375704ffb19cffaea12b2d143763c5fb4aba2ea390f679bc3981b
 EBUILD ffmpeg-0.7.8.ebuild 8434 RMD160 ee37ec983306aaa4bf464a6bcccd7072c8490052 SHA1 7712cefb7ac062070f1d367d250204e95ea9e709 SHA256 f295745280616cc04724889e2d5b02a9648321e572c256e959989610c0b774e3
 EBUILD ffmpeg-0.9.1.ebuild 8282 RMD160 4c64863619ae9fd0826ab067d8606fe57ef61dca SHA1 fffcf0f5305619244c5c111b30e456ed3e0d12f5 SHA256 ce450519e582c01f350ce7041b522e52d0431054fc7171e230bb0b5b6db96e95
 EBUILD ffmpeg-9999.ebuild 8297 RMD160 9c384c76c9a8c5448c55637c6fe573a6bbfdceb5 SHA1 41abd3c02353c970f749f4b64efe2ab178508e84 SHA256 a92d61d0ce69cb4c8fa5c61b28821b3f48989a948ef22929e088f7306461d035
-MISC ChangeLog 74690 RMD160 a72bc035a8329b72bb6ce2cbed8b99118f6431e3 SHA1 46748a13648d8bde474afc19509b8652b69be786 SHA256 d3a342a09847769b26805299726073f3129378b28e1f96335a8145ef0630f3c3
+MISC ChangeLog 74807 RMD160 a5d6be7f7feb5d661fd2da9960a234c36e08e687 SHA1 2bb516171ee51d820703ef0dc44a8d702f58a117 SHA256 4a05640361d0a607d9d54cf960f97ed3f88c8f43b80d855700112b3b6c70b73c
 MISC metadata.xml 3187 RMD160 1449b9f14d574861c1126ae3d48b2512e5c21a10 SHA1 022bfbc48a9eeb5b35246c20709322cc1cceabaf SHA256 9e1ce3cad4c6be94e164d5df3fcf1ac38603de044be5c6bd8fa273adb4d84abb
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.18 (GNU/Linux)
 
-iEYEARECAAYFAk8j58IACgkQvFcC4BYPU0rkTQCfZj5D/Gnvc3j7yiOcQ0B15pph
-/0wAoIIQX4qU85wABSQNUhAsZYSkd8KL
-=T9X1
+iEYEARECAAYFAk8j7zQACgkQvFcC4BYPU0oERQCgpYYlsRfMrBHzS7ddwjmLfNLe
+fgkAnjzwBKJ7RDAZgNgGwBhGphrOBFpN
+=AQBt
 -----END PGP SIGNATURE-----
diff --git a/media-video/ffmpeg/ffmpeg-0.10.ebuild b/media-video/ffmpeg/ffmpeg-0.10.ebuild
new file mode 100644
index 000000000000..f8558c3c2760
--- /dev/null
+++ b/media-video/ffmpeg/ffmpeg-0.10.ebuild
@@ -0,0 +1,272 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ffmpeg-0.10.ebuild,v 1.1 2012/01/28 12:50:55 aballier Exp $
+
+EAPI="4"
+
+SCM=""
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SCM="git-2"
+	EGIT_REPO_URI="git://git.videolan.org/ffmpeg.git"
+fi
+
+inherit eutils flag-o-matic multilib toolchain-funcs ${SCM}
+
+DESCRIPTION="Complete solution to record, convert and stream audio and video. Includes libavcodec."
+HOMEPAGE="http://ffmpeg.org/"
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SRC_URI=""
+elif [ "${PV%_p*}" != "${PV}" ] ; then # Snapshot
+	SRC_URI="mirror://gentoo/${P}.tar.bz2"
+else # Release
+	SRC_URI="http://ffmpeg.org/releases/${P/_/-}.tar.bz2"
+fi
+FFMPEG_REVISION="${PV#*_p}"
+
+LICENSE="GPL-2 amr? ( GPL-3 ) encode? ( aac? ( GPL-3 ) )"
+SLOT="0"
+if [ "${PV#9999}" = "${PV}" ] ; then
+	KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86-fbsd"
+fi
+IUSE="
+	aac aacplus alsa amr ass bindist +bzip2 cdio celt cpudetection debug
+	dirac doc +encode faac frei0r gnutls gsm +hardcoded-tables ieee1394 jack
+	jpeg2k libv4l modplug mp3 network openal openssl oss pic pulseaudio
+	+qt-faststart rtmp schroedinger sdl speex static-libs test theora threads
+	truetype v4l vaapi vdpau vorbis vpx X x264 xvid +zlib
+	"
+
+# String for CPU features in the useflag[:configure_option] form
+# if :configure_option isn't set, it will use 'useflag' as configure option
+CPU_FEATURES="3dnow:amd3dnow 3dnowext:amd3dnowext altivec avx mmx mmxext:mmx2 ssse3 vis neon iwmmxt"
+
+for i in ${CPU_FEATURES}; do
+	IUSE="${IUSE} ${i%:*}"
+done
+
+RDEPEND="
+	alsa? ( media-libs/alsa-lib )
+	amr? ( media-libs/opencore-amr )
+	ass? ( media-libs/libass )
+	bzip2? ( app-arch/bzip2 )
+	cdio? ( dev-libs/libcdio )
+	celt? ( >=media-libs/celt-0.11.1 )
+	dirac? ( media-video/dirac )
+	encode? (
+		aac? ( media-libs/vo-aacenc )
+		aacplus? ( media-libs/libaacplus )
+		amr? ( media-libs/vo-amrwbenc )
+		faac? ( media-libs/faac )
+		mp3? ( >=media-sound/lame-3.98.3 )
+		theora? ( >=media-libs/libtheora-1.1.1[encode] media-libs/libogg )
+		vorbis? ( media-libs/libvorbis media-libs/libogg )
+		x264? ( >=media-libs/x264-0.0.20111017 )
+		xvid? ( >=media-libs/xvid-1.1.0 )
+	)
+	frei0r? ( media-plugins/frei0r-plugins )
+	gnutls? ( net-libs/gnutls )
+	gsm? ( >=media-sound/gsm-1.0.12-r1 )
+	ieee1394? ( media-libs/libdc1394 sys-libs/libraw1394 )
+	jack? ( media-sound/jack-audio-connection-kit )
+	jpeg2k? ( >=media-libs/openjpeg-1.3-r2 )
+	libv4l? ( media-libs/libv4l )
+	modplug? ( media-libs/libmodplug )
+	openal? ( >=media-libs/openal-1.1 )
+	pulseaudio? ( media-sound/pulseaudio )
+	rtmp? ( >=media-video/rtmpdump-2.2f )
+	sdl? ( >=media-libs/libsdl-1.2.13-r1[audio,video] )
+	schroedinger? ( media-libs/schroedinger )
+	speex? ( >=media-libs/speex-1.2_beta3 )
+	truetype? ( media-libs/freetype:2 )
+	vaapi? ( >=x11-libs/libva-0.32 )
+	vdpau? ( x11-libs/libvdpau )
+	vpx? ( >=media-libs/libvpx-0.9.6 )
+	X? ( x11-libs/libX11 x11-libs/libXext x11-libs/libXfixes )
+	zlib? ( sys-libs/zlib )
+	!media-video/qt-faststart
+"
+
+DEPEND="${RDEPEND}
+	>=sys-devel/make-3.81
+	dirac? ( dev-util/pkgconfig )
+	doc? ( app-text/texi2html )
+	gnutls? ( dev-util/pkgconfig )
+	ieee1394? ( dev-util/pkgconfig )
+	libv4l? ( dev-util/pkgconfig )
+	mmx? ( dev-lang/yasm )
+	rtmp? ( dev-util/pkgconfig )
+	schroedinger? ( dev-util/pkgconfig )
+	test? ( net-misc/wget )
+	truetype? ( dev-util/pkgconfig )
+	v4l? ( sys-kernel/linux-headers )
+"
+# faac is license-incompatible with ffmpeg
+REQUIRED_USE="bindist? ( encode? ( !faac !aacplus ) !openssl )
+	libv4l? ( v4l )
+	test? ( encode zlib )"
+
+S=${WORKDIR}/${P/_/-}
+
+src_prepare() {
+	if [ "${PV%_p*}" != "${PV}" ] ; then # Snapshot
+		export revision=git-N-${FFMPEG_REVISION}
+	fi
+}
+
+src_configure() {
+	local myconf="${EXTRA_FFMPEG_CONF}"
+	# Set to --enable-version3 if (L)GPL-3 is required
+	local version3=""
+
+	# enabled by default
+	for i in debug doc network vaapi vdpau zlib; do
+		use ${i} || myconf="${myconf} --disable-${i}"
+	done
+	use bzip2 || myconf="${myconf} --disable-bzlib"
+	use sdl || myconf="${myconf} --disable-ffplay"
+
+	use cpudetection && myconf="${myconf} --enable-runtime-cpudetect"
+	use openssl && myconf="${myconf} --enable-openssl --enable-nonfree"
+	for i in gnutls ; do
+		use $i && myconf="${myconf} --enable-$i"
+	done
+
+	# Encoders
+	if use encode
+	then
+		use mp3 && myconf="${myconf} --enable-libmp3lame"
+		use aac && { myconf="${myconf} --enable-libvo-aacenc" ; version3=" --enable-version3" ; }
+		use amr && { myconf="${myconf} --enable-libvo-amrwbenc" ; version3=" --enable-version3" ; }
+		for i in theora vorbis x264 xvid; do
+			use ${i} && myconf="${myconf} --enable-lib${i}"
+		done
+		use aacplus && myconf="${myconf} --enable-libaacplus --enable-nonfree"
+		use faac && myconf="${myconf} --enable-libfaac --enable-nonfree"
+	else
+		myconf="${myconf} --disable-encoders"
+	fi
+
+	# libavdevice options
+	use cdio && myconf="${myconf} --enable-libcdio"
+	use ieee1394 && myconf="${myconf} --enable-libdc1394"
+	use openal && myconf="${myconf} --enable-openal"
+	# Indevs
+	# v4l1 is gone since linux-headers-2.6.38
+	myconf="${myconf} --disable-indev=v4l"
+	use v4l || myconf="${myconf} --disable-indev=v4l2"
+	for i in alsa oss jack ; do
+		use ${i} || myconf="${myconf} --disable-indev=${i}"
+	done
+	use X && myconf="${myconf} --enable-x11grab"
+	use pulseaudio && myconf="${myconf} --enable-libpulse"
+	use libv4l && myconf="${myconf} --enable-libv4l2"
+	# Outdevs
+	for i in alsa oss sdl ; do
+		use ${i} || myconf="${myconf} --disable-outdev=${i}"
+	done
+	# libavfilter options
+	use frei0r && myconf="${myconf} --enable-frei0r"
+	use truetype && myconf="${myconf} --enable-libfreetype"
+	use ass && myconf="${myconf} --enable-libass"
+
+	# Threads; we only support pthread for now but ffmpeg supports more
+	use threads && myconf="${myconf} --enable-pthreads"
+
+	# Decoders
+	use amr && { myconf="${myconf} --enable-libopencore-amrwb --enable-libopencore-amrnb" ; version3=" --enable-version3" ; }
+	for i in celt gsm dirac modplug rtmp schroedinger speex vpx; do
+		use ${i} && myconf="${myconf} --enable-lib${i}"
+	done
+	use jpeg2k && myconf="${myconf} --enable-libopenjpeg"
+
+	# CPU features
+	for i in ${CPU_FEATURES}; do
+		use ${i%:*} || myconf="${myconf} --disable-${i#*:}"
+	done
+	if use pic ; then
+		myconf="${myconf} --enable-pic"
+		# disable asm code if PIC is required
+		# as the provided asm decidedly is not PIC for x86.
+		use x86 && myconf="${myconf} --disable-asm"
+	fi
+
+	# Try to get cpu type based on CFLAGS.
+	# Bug #172723
+	# We need to do this so that features of that CPU will be better used
+	# If they contain an unknown CPU it will not hurt since ffmpeg's configure
+	# will just ignore it.
+	for i in $(get-flag march) $(get-flag mcpu) $(get-flag mtune) ; do
+		[ "${i}" = "native" ] && i="host" # bug #273421
+		myconf="${myconf} --cpu=${i}"
+		break
+	done
+
+	# Mandatory configuration
+	myconf="
+		--enable-gpl
+		${version3}
+		--enable-postproc
+		--enable-avfilter
+		--disable-stripping
+		${myconf}"
+
+	# cross compile support
+	if tc-is-cross-compiler ; then
+		myconf="${myconf} --enable-cross-compile --arch=$(tc-arch-kernel) --cross-prefix=${CHOST}-"
+		case ${CHOST} in
+			*freebsd*)
+				myconf="${myconf} --target-os=freebsd"
+				;;
+			mingw32*)
+				myconf="${myconf} --target-os=mingw32"
+				;;
+			*linux*)
+				myconf="${myconf} --target-os=linux"
+				;;
+		esac
+	fi
+
+	# Misc stuff
+	use hardcoded-tables && myconf="${myconf} --enable-hardcoded-tables"
+
+	cd "${S}"
+	./configure \
+		--prefix="${EPREFIX}/usr" \
+		--libdir="${EPREFIX}/usr/$(get_libdir)" \
+		--shlibdir="${EPREFIX}/usr/$(get_libdir)" \
+		--mandir="${EPREFIX}/usr/share/man" \
+		--enable-shared \
+		--cc="$(tc-getCC)" \
+		--cxx="$(tc-getCXX)" \
+		--ar="$(tc-getAR)" \
+		--optflags="${CFLAGS}" \
+		--extra-cflags="${CFLAGS}" \
+		--extra-cxxflags="${CXXFLAGS}" \
+		$(use_enable static-libs static) \
+		${myconf} || die
+}
+
+src_compile() {
+	emake
+
+	if use qt-faststart; then
+		tc-export CC
+		emake -C tools qt-faststart
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install install-man
+
+	dodoc Changelog README INSTALL
+	dodoc -r doc/*
+
+	if use qt-faststart; then
+		dobin tools/qt-faststart
+	fi
+}
+
+src_test() {
+	LD_LIBRARY_PATH="${S}/libpostproc:${S}/libswscale:${S}/libswresample:${S}/libavcodec:${S}/libavdevice:${S}/libavfilter:${S}/libavformat:${S}/libavutil" \
+		emake fate
+}