Version bump.

Package-Manager: portage-2.1.3.15

5 files changed, 201 insertions, 1 deletions

diff --git a/net-wireless/bluez-libs/bluez-libs-3.22.ebuild b/net-wireless/bluez-libs/bluez-libs-3.22.ebuild
new file mode 100644
index 000000000000..b713126a1a05
--- /dev/null
+++ b/net-wireless/bluez-libs/bluez-libs-3.22.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/bluez-libs/bluez-libs-3.22.ebuild,v 1.1 2007/10/26 10:45:39 betelgeuse Exp $
+
+DESCRIPTION="Bluetooth Userspace Libraries"
+HOMEPAGE="http://bluez.sourceforge.net/"
+SRC_URI="http://bluez.sourceforge.net/download/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
+
+IUSE="debug"
+DEPEND="!net-wireless/bluez-sdp"
+RDEPEND="${DEPEND}"
+
+src_compile() {
+	econf $(use_enable debug) || die "econf failed"
+	if use debug ; then
+		echo "#define SDP_DEBUG 1" >> config.h
+	fi
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "make install failed"
+	dodoc AUTHORS ChangeLog README || die
+}
+
+pkg_postinst() {
+	elog "If you are upgrading from =net-wireless/bluez-util-2*,"
+	elog "the ABI version of libbluetooth has changed."
+	elog "Please run:"
+	elog "  revdep-rebuild --library libbluetooth.so.1"
+}
diff --git a/net-wireless/bluez-libs/files/digest-bluez-libs-3.22 b/net-wireless/bluez-libs/files/digest-bluez-libs-3.22
new file mode 100644
index 000000000000..4e57019cb145
--- /dev/null
+++ b/net-wireless/bluez-libs/files/digest-bluez-libs-3.22
@@ -0,0 +1,3 @@
+MD5 b3bf8c92ed05633503be8a85d9785452 bluez-libs-3.22.tar.gz 309260
+RMD160 a566d286981c9d250feaea2dde3dffa201fb1783 bluez-libs-3.22.tar.gz 309260
+SHA256 d4e47060a4ba12f86d490891dd2e0cdf44aa02c11cd16be3e7d5362c4dcff95e bluez-libs-3.22.tar.gz 309260
diff --git a/net-wireless/bluez-utils/ChangeLog b/net-wireless/bluez-utils/ChangeLog
index 6b4257e647f6..88f853c67e41 100644
--- a/net-wireless/bluez-utils/ChangeLog
+++ b/net-wireless/bluez-utils/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-wireless/bluez-utils
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/bluez-utils/ChangeLog,v 1.108 2007/10/06 00:40:05 betelgeuse Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/bluez-utils/ChangeLog,v 1.109 2007/10/26 10:45:38 betelgeuse Exp $
+
+*bluez-utils-3.22 (26 Oct 2007)
+
+  26 Oct 2007; Petteri Räty <betelgeuse@gentoo.org>
+  +bluez-utils-3.22.ebuild:
+  Version bump.
 
 *bluez-utils-3.20 (06 Oct 2007)
 
diff --git a/net-wireless/bluez-utils/bluez-utils-3.22.ebuild b/net-wireless/bluez-utils/bluez-utils-3.22.ebuild
new file mode 100644
index 000000000000..e3b36b838d33
--- /dev/null
+++ b/net-wireless/bluez-utils/bluez-utils-3.22.ebuild
@@ -0,0 +1,153 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/bluez-utils/bluez-utils-3.22.ebuild,v 1.1 2007/10/26 10:45:38 betelgeuse Exp $
+
+inherit autotools eutils
+
+DESCRIPTION="Bluetooth Tools and System Daemons for Linux"
+HOMEPAGE="http://bluez.sourceforge.net/"
+SRC_URI="http://bluez.sourceforge.net/download/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~sh ~sparc ~x86"
+
+IUSE="alsa cups debug examples gstreamer hal old-daemons test-programs usb"
+
+DEPEND="
+	>=net-wireless/bluez-libs-${PV}
+	alsa? ( media-libs/alsa-lib )
+	gstreamer? (
+		>=media-libs/gstreamer-0.10
+		>=media-libs/gst-plugins-base-0.10 )
+	hal? ( sys-apps/hal )
+	usb? ( dev-libs/libusb )
+	cups? ( net-print/cups )
+	sys-fs/udev
+	dev-libs/glib
+	sys-apps/dbus"
+
+src_unpack() {
+	unpack ${A}
+	# bundled glib
+	cd "${S}"
+	rm -r eglib/{*.c,*.h}  || die
+	if use cups; then
+		epatch "${FILESDIR}/3.11/cups-location.patch"
+		eautoreconf
+	fi
+}
+
+src_compile() {
+	# the order is the same as ./configure --help
+
+	# we don't need the other daemons either with the new
+	# service architechture
+	# hcid has in integrated sdpd now that we use
+
+	# These are currently under work and don't work properly:
+	# --enable-sync
+	# --enable-obex
+
+	econf \
+		$(use_enable debug) \
+		--enable-inotify \
+		$(use_enable hal) \
+		$(use_enable usb) \
+		$(use_enable alsa) \
+		--enable-glib  \
+		$(use_enable gstreamer) \
+		--disable-obex \
+		--enable-network \
+		--enable-serial \
+		--enable-input \
+		--enable-audio \
+		--disable-sync \
+		$(use_enable examples echo) \
+		--enable-hcid \
+		$(use_enable test-programs test) \
+		$(use_enable old-daemons sdpd) \
+		$(use_enable old-daemons hidd) \
+		$(use_enable old-daemons pand) \
+		$(use_enable cups) \
+		--enable-configfiles \
+		--disable-initscripts \
+		--disable-pcmciarules \
+		--enable-bccmd \
+		--enable-avctrl \
+		--enable-hid2hci \
+		--enable-dfutool \
+		--localstatedir=/var \
+		|| die "econf failed"
+
+	emake || die "emake failed"
+}
+
+src_install() {
+	make DESTDIR="${D}" install || die "make install failed"
+
+	dodoc AUTHORS ChangeLog README || die
+
+	# a very simple example daemon
+	dobin daemon/passkey-agent || die
+
+	newinitd "${FILESDIR}/3.11/bluetooth-init.d" bluetooth || die
+	newconfd "${FILESDIR}/3.11/bluetooth-conf.d" bluetooth || die
+
+	if use old-daemons; then
+		sed -re 's/^(Autostart=)true/\1false/' \
+			-i "${D}/etc/bluetooth/input.service" || die
+		newconfd "${FILESDIR}/3.11/conf.d-hidd" hidd || die
+		newinitd "${FILESDIR}/3.11/init.d-hidd" hidd || die
+	fi
+
+	# bug #84431
+	insinto /etc/udev/rules.d/
+	newins "${FILESDIR}/${PN}-3.10.1-udev.rules" 70-bluetooth.rules || die
+	newins "${S}/scripts/bluetooth.rules" 70-bluetooth-pcmcia.rules || die
+
+	exeinto /lib/udev/
+	newexe "${FILESDIR}/${PN}-3.10.1-udev.script" bluetooth.sh || die
+	doexe  "${S}/scripts/bluetooth_serial" || die
+}
+
+pkg_postinst() {
+	udevcontrol reload_rules && udevtrigger
+
+	elog
+	elog "To use dial up networking you must install net-dialup/ppp."
+	elog ""
+	elog "Since 3.0 bluez has changed the passkey handling to use a dbus based"
+	elog "API so please remember to update your /etc/bluetooth/hcid.conf."
+	elog "For a password agent, there is for example net-wireless/bluez-gnome"
+	elog "for gnome and net-wireless/kdebluetooth for kde."
+	elog ""
+	elog "Since 3.10.1 we don't install the old style daemons any more but rely"
+	elog "on the new service architechture:"
+	elog "	http://wiki.bluez.org/wiki/Services"
+	elog ""
+	elog "3.15 adds support for the audio service. See"
+	elog "http://wiki.bluez.org/wiki/HOWTO/AudioDevices for configuration help."
+	elog ""
+	elog "Edit /etc/bluetooth/*.service to enable the services."
+	elog "Use the old-daemons use flag to get the old daemons like hidd"
+	elog "installed. Please note that the init script doesn't stop the old"
+	elog "daemons after you update it so it's recommended to run:"
+	elog "  /etc/init.d/bluetooth stop"
+	elog "before updating your configuration files or you can manually kill"
+	elog "the extra daemons you previously enabled in /etc/conf.d/bluetooth."
+	elog ""
+	elog "If you want to use rfcomm as a normal user, you need to add the user"
+	elog "to the uucp group."
+	elog ""
+	if use old-daemons; then
+		elog "The hidd init script was installed because you have the old-daemons"
+		elog "use flag on. It is not started by default via udev so please add it"
+		elog "to the required runleves using rc-update <runlevel> add hidd. If"
+		elog "you need init scripts for the other daemons, please file requests"
+		elog "to https://bugs.gentoo.org."
+	else
+		elog "The bluetooth service should be started automatically by udev"
+		elog "when the required hardware is inserted next time."
+	fi
+}
diff --git a/net-wireless/bluez-utils/files/digest-bluez-utils-3.22 b/net-wireless/bluez-utils/files/digest-bluez-utils-3.22
new file mode 100644
index 000000000000..f7d3092ab7ad
--- /dev/null
+++ b/net-wireless/bluez-utils/files/digest-bluez-utils-3.22
@@ -0,0 +1,3 @@
+MD5 c183dedb12c79433adfaa102dce2b0d4 bluez-utils-3.22.tar.gz 918205
+RMD160 42f95a5a01dfb22049241aa249806df01ac8213a bluez-utils-3.22.tar.gz 918205
+SHA256 9189908fbb4ef68fc7c7353cbe31e2bada51b3021912e005d549fe03d1729f71 bluez-utils-3.22.tar.gz 918205