http://my.opera.com/desktopteam/blog/2011/06/09/re-speed-dial

Package-Manager: portage-2.2.0_alpha38/cvs/Linux x86_64

3 files changed, 247 insertions, 5 deletions

diff --git a/www-client/opera-next/ChangeLog b/www-client/opera-next/ChangeLog
index 73ef62a3d600..2f10bcd729c1 100644
--- a/www-client/opera-next/ChangeLog
+++ b/www-client/opera-next/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for www-client/opera-next
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/opera-next/ChangeLog,v 1.16 2011/06/09 11:39:18 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/opera-next/ChangeLog,v 1.17 2011/06/09 20:17:57 jer Exp $
+
+*opera-next-11.50.1037 (09 Jun 2011)
+
+  09 Jun 2011; Jeroen Roovers <jer@gentoo.org> +opera-next-11.50.1037.ebuild:
+  http://my.opera.com/desktopteam/blog/2011/06/09/re-speed-dial
 
 *opera-next-11.50.1036 (09 Jun 2011)
 
diff --git a/www-client/opera-next/Manifest b/www-client/opera-next/Manifest
index 79462a37559a..46adb87b01b0 100644
--- a/www-client/opera-next/Manifest
+++ b/www-client/opera-next/Manifest
@@ -31,6 +31,9 @@ DIST opera-next-11.50-1035.x86_64.linux.tar.xz 11602508 RMD160 cf82dfc340cc66226
 DIST opera-next-11.50-1036.i386.freebsd.tar.xz 10883916 RMD160 1d6397a08cff90fc099c2f01cbe149adbf69d41e SHA1 a2c6d61eb5c79dda5326b6df3ffb22ee092b95a4 SHA256 e82e91b485a6ad237e30e0f64748e65c4dd42de7eea0ee96be3a241cdb9eba63
 DIST opera-next-11.50-1036.i386.linux.tar.xz 10836684 RMD160 8a97c5d676fa1800815e46c681cf77edb9b435af SHA1 20441bedef0971de9edcb4ab398f9a4ecd0e4a49 SHA256 f065e1ffba2dc0486bcce3e6e56a2a9c639855ca9ea7aa74266fe5a458add794
 DIST opera-next-11.50-1036.x86_64.linux.tar.xz 11600752 RMD160 e3dcac546a6f164c26a45e0d84553198d9ea2159 SHA1 7ce1c66908d429078bb8ed0a02069ecfe8c7e694 SHA256 29b781cabb8dff9a0f3bc1332df8334feacc34f780c024f9e01f4df048a2cc4b
+DIST opera-next-11.50-1037.i386.freebsd.tar.xz 10883060 RMD160 959a1399ce5ace9136e8902eeb05e0790f89ffbd SHA1 3e6ca86204874886582b6305914aa030b17c5f85 SHA256 c49688a1808df6c206f0e6a4279c47b8033d52681ef1e82b545cfa33857330d4
+DIST opera-next-11.50-1037.i386.linux.tar.xz 10835256 RMD160 4315924e44c08f17ffa237ff0b216ba03127be6c SHA1 aa2854dab38712ebc7d0984349b1b6c6313a6345 SHA256 608fba2e024b4200a6ca511a67ac0f7ee8f996c40e4be212a081db6864afa005
+DIST opera-next-11.50-1037.x86_64.linux.tar.xz 11602112 RMD160 0eb5c609980e476eb6b1e22f33fccc0b8b2c94bf SHA1 01adb32540568227688b4491ae8bebc3ab6b65c4 SHA256 898c0d081639f70aa839d92a1f7ac328f0b393264e4bdd8f789ffe73ec44d7df
 EBUILD opera-next-11.50.1009.ebuild 5938 RMD160 88b7c94fb996540e5a211fcf2ce278ac2dff6cc8 SHA1 e8b73ada5b8ce747ef697229b6cca2b3d67052d8 SHA256 68106e4e0a47620e1ca868822efcc9ae717cc6663fb30a9e830662fa1ebee498
 EBUILD opera-next-11.50.1015.ebuild 5946 RMD160 8da970b0a9d46985bb7ec456b3f327d2bef98f77 SHA1 1c7c770600862cd83f8b80837b857314c4f5390c SHA256 97cddad9846cf6e75202a619c0072df215f46d4d5b403c7af0ad8ff4c66d5964
 EBUILD opera-next-11.50.1016.ebuild 5947 RMD160 fa066a659b2b0d2fdbb9afb8dda8742f3717ce44 SHA1 6fee78bed4ca2a75d12fa9c3386fa8fadc083d7e SHA256 22708e79fa8c6b392b7919253a6f2a31a8a468c6a9277dd81672c668bede3035
@@ -41,12 +44,13 @@ EBUILD opera-next-11.50.1027.ebuild 5938 RMD160 365cffea47d27c23f37d02590da7ebee
 EBUILD opera-next-11.50.1031.ebuild 6197 RMD160 bfa4cc0a6ea5804dfe28d2511d867ce8ad3ccaef SHA1 88c237a903bde66607e808bf469640c13bba6bba SHA256 e9e5fcdb8330552beab75a8b38b839f344f6a41f796353217dccdd6ebeef8386
 EBUILD opera-next-11.50.1035.ebuild 6195 RMD160 d039a248078cb351911758f8facac0d909fb603d SHA1 7882b3e5ab1bbd9e325e51870c4f61b312eb3a7f SHA256 ea11842045c8f6dce62e8a507941f27d62fb83482e0e583fcfb33a4b4be27ef6
 EBUILD opera-next-11.50.1036.ebuild 6198 RMD160 88771dc59bb940fdb2434a99b75b1a2ddc68b268 SHA1 340f2ea00e06caef3a6204e7f9ba0e1e6b0b300d SHA256 db7d99ad71dd7f8bd657df81c9d09c618af01597145480a7cf767ac340d0959c
-MISC ChangeLog 2965 RMD160 a7391126c0c14c1e314daf96c177dffef5a4b744 SHA1 74a576cbf1beac201038f35470a3c1f0562b8eee SHA256 475b1ec61df4f2a1aeb3395ea028742433752f2af0daa6925fa05657f6780024
+EBUILD opera-next-11.50.1037.ebuild 6193 RMD160 39ef9c3bdd07e147091ad72df395a09f7df03b34 SHA1 1a9f7e9409687b7fc25e68b64a1b4c27b910c933 SHA256 5d778bd48b461b7b58a4dc6a426abfc373a7beade43b0ba562932f3368cbbfab
+MISC ChangeLog 3146 RMD160 836dbe3746ea93fde91d6ab15fbded3ec931840a SHA1 35d4bfbc8b5f72f2f89347e3e859d63aafbbb44a SHA256 f239b42d7684516a5fe804300295f2c2e72b8ed58c0acc83ba6776499d0c13be
 MISC metadata.xml 1547 RMD160 465d146bcfdb6553f7f0ab2dddd68c4dcb2e7731 SHA1 1afb7e0ccc0833ba0eb73be38b282b66ad629ff6 SHA256 5cfc6e7cbf3c454d563eb407b4569f0f5a9b3ce7770026d6055f27211d481915
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.17 (GNU/Linux)
 
-iEYEARECAAYFAk3wsOwACgkQVWmRsqeSphNiuACcCu3BZPoIBKSkwzNSfKyqOl+t
-QDcAn3G+1LDsfPjM+7OfhMk4Eq0I7bYt
-=vJR+
+iEYEARECAAYFAk3xKnsACgkQVWmRsqeSphMW7QCdG4v9Vz6WRQVzan2TsUtcZB7V
+0JEAn08/zsW2P8O5b/YfBKIrpsxhMCm4
+=elmS
 -----END PGP SIGNATURE-----
diff --git a/www-client/opera-next/opera-next-11.50.1037.ebuild b/www-client/opera-next/opera-next-11.50.1037.ebuild
new file mode 100644
index 000000000000..500a7b194ac4
--- /dev/null
+++ b/www-client/opera-next/opera-next-11.50.1037.ebuild
@@ -0,0 +1,233 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/opera-next/opera-next-11.50.1037.ebuild,v 1.1 2011/06/09 20:17:57 jer Exp $
+
+EAPI="3"
+
+inherit eutils fdo-mime gnome2-utils multilib pax-utils versionator
+
+DESCRIPTION="A fast and secure web browser and Internet suite"
+HOMEPAGE="http://www.opera.com/"
+
+SLOT="0"
+LICENSE="OPERA-11 LGPL-2 LGPL-3"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd"
+IUSE="elibc_FreeBSD gtk kde +gstreamer"
+
+O_V="$(get_version_component_range 1-2)" # Major version, i.e. 11.00
+O_B="$(get_version_component_range 3)"   # Build version, i.e. 1156
+
+O_D="preg_${O_V}-${O_B}"
+O_P="${PN}-${O_V}-${O_B}"
+O_U="http://snapshot.opera.com/unix/"
+
+SRC_URI="
+	amd64? ( ${O_U}${O_D}/${O_P}.x86_64.linux.tar.xz )
+	x86? ( ${O_U}${O_D}/${O_P}.i386.linux.tar.xz )
+	x86-fbsd? ( ${O_U}${O_D}/${O_P}.i386.freebsd.tar.xz )
+"
+
+OPREFIX="/usr/$(get_libdir)"
+
+QA_DT_HASH="${OPREFIX}/${PN}/.*"
+QA_PRESTRIPPED="${OPREFIX}/${PN}/.*"
+
+O_LINGUAS="
+	af az be bg cs da de el en-GB es-ES es-LA et fi fr fr-CA fy gd hi hr hu id
+	it ja ka ko lt me mk ms nb nl nn pl pt pt-BR ro ru sk sr sv ta te th tl tr
+	uk uz vi zh-CN zh-TW
+"
+
+for O_LINGUA in ${O_LINGUAS}; do
+	IUSE="${IUSE} linguas_${O_LINGUA/-/_}"
+done
+
+DEPEND="
+	>=sys-apps/sed-4
+	app-arch/xz-utils
+"
+GTKRDEPEND="
+	dev-libs/atk
+	dev-libs/glib:2
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:2
+	x11-libs/pango
+	x11-libs/pixman
+"
+KDERDEPEND="
+	kde-base/kdelibs
+	x11-libs/qt-core
+	x11-libs/qt-gui
+"
+GSTRDEPEND="
+	dev-libs/glib
+	dev-libs/libxml2
+	media-plugins/gst-plugins-meta
+	media-libs/gstreamer
+"
+RDEPEND="
+	media-libs/fontconfig
+	media-libs/freetype
+	sys-apps/util-linux
+	sys-libs/zlib
+	virtual/opengl
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXft
+	x11-libs/libXrender
+	gtk? ( ${GTKRDEPEND} )
+	kde? ( ${KDERDEPEND} )
+	gstreamer? ( ${GSTRDEPEND} )
+"
+
+pkg_setup() {
+	echo -e \
+		" ${GOOD}****************************************************${NORMAL}"
+	elog "If you seek support, please file a bug report at"
+	elog "https://bugs.gentoo.org and post the output of"
+	elog " \`emerge --info =${CATEGORY}/${P}'"
+	echo -e \
+		" ${GOOD}****************************************************${NORMAL}"
+}
+
+src_unpack() {
+	unpack ${A}
+	mv -v ${PN}* "${S}" || die
+}
+
+src_prepare() {
+	local LNGDIR="share/${PN}/locale"
+
+	# Count linguas
+	count() { echo ${#}; }
+	local lingua_count=$(count ${O_LINGUAS} en)
+	local locale_count=$(count ${LNGDIR}/*)
+	[[ ${lingua_count} = ${locale_count} ]] \
+		|| die "Number of LINGUAS does not match number of locales"
+	unset count
+
+	# Remove unwanted linguas
+	einfo "Keeping these locales (linguas): ${LINGUAS}."
+	for LINGUA in ${O_LINGUAS}; do
+		if ! use linguas_${LINGUA/-/_}; then
+			LINGUA=$(find "${LNGDIR}" -maxdepth 1 -type d -iname ${LINGUA/_/-})
+			rm -r "${LINGUA}" || die "The list of linguas needs to be fixed"
+		fi
+	done
+
+	# Remove doc directory but keep the LICENSE under another name (bug #315473)
+	mv share/doc/${PN}/LICENSE share/${PN}/defaults/license.txt
+	rm -rf share/doc
+	for locale in share/${PN}/locale/*; do
+		rm -f "${locale}/license.txt"
+		ln -sn /usr/share/${PN}/defaults/license.txt "${locale}/license.txt" \
+			|| die "ln -sn license.txt"
+	done
+
+	# Remove package directory
+	rm -rf share/${PN}/package
+
+	# Leave libopera*.so only if the user chooses
+	if ! use gtk; then
+		rm lib/${PN}/liboperagtk.so || die "rm liboperagtk.so failed"
+	fi
+	if ! use kde; then
+		rm lib/${PN}/liboperakde4.so || die "rm liboperakde4.so failed"
+	fi
+
+	# Unzip the man pages before sedding
+	gunzip share/man/man1/* || die "gunzip failed"
+
+	# Replace PREFIX, SUFFIX and PN in various files
+	sed -i \
+		-e "s:@@{PREFIX}:/usr:g" \
+		-e "s:@@{SUFFIX}::g" \
+		-e "s:@@{_SUFFIX}::g" \
+		-e "s:@@{USUFFIX}::g" \
+		-e "s:opera:${PN}:g" \
+		share/man/man1/* \
+		share/applications/${PN}-browser.desktop \
+		|| die "sed failed"
+
+	# Create /usr/bin/opera wrapper
+	echo '#!/bin/sh' > ${PN}
+	echo 'export OPERA_DIR=/usr/share/'"${PN}" >> ${PN}
+	echo 'export OPERA_PERSONALDIR=${OPERA_PERSONALDIR:-"${HOME}/.'${PN}'"}' \
+		>> ${PN}
+	echo 'exec '"${OPREFIX}/${PN}/${PN}"' "$@"' >> ${PN}
+
+	# Fix libdir in defaults/pluginpath.ini
+	sed -i \
+		share/${PN}/defaults/pluginpath.ini \
+		-e "s|/usr/lib32|${OPREFIX}|g" \
+		-e '/netscape/{s|[0-1]|2|g}' \
+		|| die "sed pluginpath.ini failed"
+
+	# Change libz.so.3 to libz.so.1 for gentoo/freebsd
+	if use elibc_FreeBSD; then
+		scanelf -qR -N libz.so.3 -F "#N" lib/${PN}/ | \
+		while read i; do
+			if [[ $(strings "$i" | fgrep -c libz.so.3) -ne 1 ]];
+			then
+				export SANITY_CHECK_LIBZ_FAILED=1
+				break
+			fi
+			sed -i \
+				"$i" \
+				-e 's/libz\.so\.3/libz.so.1/g'
+		done
+		[[ "$SANITY_CHECK_LIBZ_FAILED" = "1" ]] \
+			&& die "failed to change libz.so.3 to libz.so.1"
+	fi
+}
+
+src_install() {
+	# We install into usr instead of opt as Opera does not support the latter
+	dodir /usr
+	mv lib/ "${D}/${OPREFIX}" || die "mv lib/ failed"
+	mv share/ "${D}/usr/" || die "mv share/ failed"
+
+	# Install startup scripts
+	dobin ${PN} || die "dobin failed"
+
+	# Stop revdep-rebuild from checking opera binaries
+	dodir /etc/revdep-rebuild
+	echo "SEARCH_DIRS_MASK=\"${OPREFIX}/${PN}\"" \
+		> "${D}"/etc/revdep-rebuild/90${PN}
+
+	# Set PaX markings for hardened/PaX (bug #344267)
+	pax-mark m \
+		"${D}/${OPREFIX}/${PN}/${PN}" \
+		"${D}/${OPREFIX}/${PN}/operaplugincleaner" \
+		"${D}/${OPREFIX}/${PN}/operapluginwrapper"
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	elog "To change the UI language, choose [Tools] -> [Preferences], open the"
+	elog "[General] tab, click on [Details...] then [Choose...] and point the"
+	elog "file chooser at /usr/share/${PN}/locale/, then enter the"
+	elog "directory for the language you want and [Open] the .lng file."
+
+	if use elibc_FreeBSD; then
+		elog
+		elog "To improve shared memory usage please set:"
+		elog "$ sysctl kern.ipc.shm_allow_removed=1"
+	fi
+
+	# Update desktop file database and gtk icon cache (bug #334993)
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+}
+
+pkg_postrm() {
+	# Update desktop file database and gtk icon cache (bug #334993)
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+}