Version bump, performance improvement, reduced memory consumption, new backends for webkit-gtk and libsoup, and bugfixes. ~hppa and ~ppc64 keywords temporarly removed pending bug #272194

Package-Manager: portage-2.2_rc33/cvs/Linux x86_64

4 files changed, 161 insertions, 3 deletions

diff --git a/x11-misc/google-gadgets/ChangeLog b/x11-misc/google-gadgets/ChangeLog
index ca6885af1806..2285a821cfef 100644
--- a/x11-misc/google-gadgets/ChangeLog
+++ b/x11-misc/google-gadgets/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for x11-misc/google-gadgets
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/google-gadgets/ChangeLog,v 1.24 2009/04/11 19:30:29 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/google-gadgets/ChangeLog,v 1.25 2009/06/01 22:50:41 voyageur Exp $
+
+*google-gadgets-0.11.0 (01 Jun 2009)
+
+  01 Jun 2009; Bernard Cafarelli <voyageur@gentoo.org>
+  +google-gadgets-0.11.0.ebuild, metadata.xml:
+  Version bump, performance improvement, reduced memory consumption, new
+  backends for webkit-gtk and libsoup, and bugfixes. ~hppa and ~ppc64
+  keywords temporarly removed pending bug #272194
 
   11 Apr 2009; Raúl Porcel <armin76@gentoo.org>
   google-gadgets-0.10.5.ebuild:
diff --git a/x11-misc/google-gadgets/Manifest b/x11-misc/google-gadgets/Manifest
index 6dc281881391..176e9f937d62 100644
--- a/x11-misc/google-gadgets/Manifest
+++ b/x11-misc/google-gadgets/Manifest
@@ -4,8 +4,10 @@ AUX google-gadgets-0.10.4-xulrunner-1.9.1.patch 2805 RMD160 949e5d8192f92da33c0a
 DIST google-gadgets-for-linux-0.10.3.tar.bz2 2310377 RMD160 6256a0e34e4c157aef4b88537c54192d93f3af0c SHA1 a067ba48fa195bbeed407dc0e528e608e59156ee SHA256 fe63758aacb3842829c5a6d7698152b34becb44fe3e2d84d9706bf4ea9956c1e
 DIST google-gadgets-for-linux-0.10.4.tar.bz2 2384725 RMD160 d47586e7a97e27c3a2a0a4dbb11087b0a2b98b5d SHA1 d1d53b7a1fff2dd3bbe7670ebaf4a9a0996d92a9 SHA256 03ff4140070ae7518a40fef94993c1f32b02d8f65f88f69363447cff501977df
 DIST google-gadgets-for-linux-0.10.5.tar.bz2 2429875 RMD160 974f135f8e1e15732f7492ab6ba5c43bc9d44daa SHA1 c85136c862384d789dc0fab7bc4d8b9d82572f30 SHA256 944810df4b134542a1e675e6d9518503466ce9398e8bfca5e3637d994ef5038d
+DIST google-gadgets-for-linux-0.11.0.tar.bz2 2526161 RMD160 f9f8b7e7462ab26cce87f1632e01f035a67249fc SHA1 68342edf0cc168c32c424f8bbb59f84863aca5c4 SHA256 ee77f58866e94ed6ef592650329d30e81ad58cf44e418b36c9218734db02b82f
 EBUILD google-gadgets-0.10.3.ebuild 4138 RMD160 ebca1f9c2f520b51cc252435ce2181ffb68de639 SHA1 3ddbd963ae7122910b8f15589d9073b96e6e8e23 SHA256 85e5c00decff6dd2e8763545d0730e747d3e8063c6065237520fdbc4ea7fda71
 EBUILD google-gadgets-0.10.4.ebuild 4288 RMD160 adf8a9965d0b787a09442129e90b559d52c40ab4 SHA1 668c296fbe7e9090c6baf7f69862ef323bbce0fc SHA256 7188126e09438f76e6f0251058a79bfa06fb0472828f0d1e34d77250d804a0f5
 EBUILD google-gadgets-0.10.5.ebuild 4184 RMD160 38f538b544ed6bf32c7b4355773c2fd14000353f SHA1 5ba9dc86d187f151dfe6560d310f910ca990998b SHA256 9199428814ead82d90443cb81e3cd34ad7f7b8d791db43bea2b0479b058873eb
-MISC ChangeLog 4940 RMD160 0fc2caf7964a3f99b2724acb87d5da5910109894 SHA1 a44391d44f1b191226c320e3662d9cd882cdf078 SHA256 105d3d10e04019eade2465ff1307bd37e970c67ba59ce10e2d14f46e11dccdb2
-MISC metadata.xml 260 RMD160 af6650245d6ccbcbdb2e829cd5d7be36bef71058 SHA1 a09861327ac9225fbbfafb891a8998f2ea6c73bb SHA256 1dfcd18a238fd7d714e848ad5661fbe98c7556e276b054d962cccfe44f7240f6
+EBUILD google-gadgets-0.11.0.ebuild 4534 RMD160 294f6400ec956f30938af6a38bacda5869ee36fd SHA1 017e14ed714a3ab69f8b568d4600190c5571f0d4 SHA256 7c4a1d1c8615976377b25d8e005c67972f700739bc5785c98d3a0b6f3519ad23
+MISC ChangeLog 5275 RMD160 bfa23123126f2cdfe0279e77e4973b9d8d774c8a SHA1 92a0dae6294bbaa0b8ced4a2b97e117693b59bcb SHA256 51c999d0fc4e82975636b485113dda8c7b2077ae196c83ad3e7f4face87f5f65
+MISC metadata.xml 486 RMD160 b08018667c1efbe528ecbbb88b4a0fe5932464f9 SHA1 6d0a5c446e901d47be27b4c707e986b8b8964c64 SHA256 200d5369ac38f83f0fe143ab1d87c734b88e52eb6eca146208fd21dec5776dda
diff --git a/x11-misc/google-gadgets/google-gadgets-0.11.0.ebuild b/x11-misc/google-gadgets/google-gadgets-0.11.0.ebuild
new file mode 100644
index 000000000000..6d8f90afeed5
--- /dev/null
+++ b/x11-misc/google-gadgets/google-gadgets-0.11.0.ebuild
@@ -0,0 +1,144 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/google-gadgets/google-gadgets-0.11.0.ebuild,v 1.1 2009/06/01 22:50:41 voyageur Exp $
+
+EAPI=2
+
+inherit base autotools multilib eutils fdo-mime
+
+MY_PN=${PN}-for-linux
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Cool gadgets from Google for your Desktop"
+HOMEPAGE="http://code.google.com/p/google-gadgets-for-linux/"
+SRC_URI="http://${MY_PN}.googlecode.com/files/${MY_P}.tar.bz2"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~x86"
+IUSE="+dbus debug +gtk +qt4 +gstreamer networkmanager soup startup-notification webkit"
+
+# Weird things happen when we start mix-n-matching, so for the time being
+# I've just locked the deps to the versions I had as of Summer 2008. With any
+# luck, they'll be stable when we get to stabling this package.
+
+RDEPEND="
+	>=dev-libs/libxml2-2.6.32
+	net-libs/xulrunner:1.9
+	sys-libs/zlib
+	x11-libs/libX11
+	x11-libs/libXext
+	dbus? ( sys-apps/dbus )
+	gstreamer? (
+		>=media-libs/gstreamer-0.10.19
+		>=media-libs/gst-plugins-base-0.10.19
+	)
+	gtk? (
+		>=dev-libs/atk-1.22.0
+		gnome-base/librsvg
+		>=net-misc/curl-7.18.2
+		>=x11-libs/cairo-1.6.4
+		>=x11-libs/gtk+-2.12.10
+		>=x11-libs/pango-1.20.3
+		dbus? ( >=dev-libs/dbus-glib-0.74 )
+	)
+	networkmanager? ( net-misc/networkmanager )
+	qt4? (
+		>=x11-libs/qt-core-4.4.0
+		>=x11-libs/qt-opengl-4.4.0
+		>=x11-libs/qt-script-4.4.0
+		>=x11-libs/qt-webkit-4.4.0
+		>=x11-libs/qt-xmlpatterns-4.4.0
+		dbus? ( >=x11-libs/qt-dbus-4.4.0 )
+	)
+	soup? ( >=net-libs/libsoup-2.26 )
+	startup-notification? ( x11-libs/startup-notification )
+	webkit? ( >=net-libs/webkit-gtk-1.0.3 )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/pkgconfig-0.20
+"
+
+S="${WORKDIR}/${MY_P}"
+
+RESTRICT="test"
+
+pkg_setup() {
+	# If a non-google, non-qt4 and non-gtk host system for google-gadgets is ever developed,
+	# I'll consider changing the error below.
+	if ! use gtk && ! use qt4; then
+		eerror "You must choose which toolkit to build for. Either qt4 or gtk can be"
+		eerror "chosen. For qt4, see also above. To enable \$toolkit, do:"
+		eerror "echo \"${CATEGORY}/${PN} \$toolkit\" >> /etc/portage/package.use"
+		die "You need to choose a toolkit"
+	fi
+
+	if ! use gstreamer; then
+		ewarn "Disabling gstreamer disables the multimedia functions of ${PN}."
+		ewarn "This is not recommended. To enable gstreamer, do:"
+		ewarn "echo \"${CATEGORY}/${PN} gstreamer\" >> /etc/portage/package.use"
+	fi
+}
+
+src_prepare() {
+	sed -i -r \
+		-e '/^GGL_SYSDEPS_INCLUDE_DIR/ c\GGL_SYSDEPS_INCLUDE_DIR=$GGL_INCLUDE_DIR' \
+		configure.ac||die "404"
+	eautoreconf
+}
+
+src_configure() {
+	#For the time being, the smjs-script runtime is required for both gtk and qt
+	#versions, but the goal is to make the qt4 version depend only on qt-script.
+	has_pkg_smjs=no \
+	econf	--disable-dependency-tracking \
+		--disable-update-desktop-database \
+		--disable-update-mime-database \
+		--disable-werror \
+		--enable-libxml2-xml-parser \
+		--enable-smjs-script-runtime \
+		--with-gtkmozembed=libxul \
+		--with-smjs-cppflags=-I/usr/include/nspr \
+		--with-smjs-libdir=/usr/$(get_libdir)/xulrunner-1.9 \
+		--with-smjs-incdir=/usr/include/xulrunner-1.9/unstable \
+		--with-browser-plugins-dir=/usr/$(get_libdir)/nsbrowser/plugins \
+		--with-ssl-ca-file=/etc/ssl/certs/ca-certificates.crt \
+		--with-oem-brand=Gentoo \
+		$(use_enable debug) \
+		$(use_enable dbus libggadget-dbus) \
+		$(use_enable gstreamer gst-audio-framework) \
+		$(use_enable gstreamer gst-video-element) \
+		$(use_enable soup soup-xml-http-request) \
+		$(use_enable webkit webkit-script-runtime) \
+		$(use_enable webkit gtkwebkit-browser-element) \
+		$(use_enable gtk gtk-host) \
+		$(use_enable gtk libggadget-gtk ) \
+		$(use_enable gtk gtkmoz-browser-element) \
+		$(use_enable gtk gtk-edit-element) \
+		$(use_enable gtk gtk-flash-element) \
+		$(use_enable gtk gtk-system-framework) \
+		$(use_enable gtk curl_xml_http_request) \
+		$(use_enable qt4 qt-host) \
+		$(use_enable qt4 libggadget-qt) \
+		$(use_enable qt4 qt-edit-framework) \
+		$(use_enable qt4 qt-system-framework) \
+		$(use_enable qt4 qtwebkit-browser-element) \
+		$(use_enable qt4 qt-xml-http-request) \
+		$(use_enable qt4 qt-script-runtime)
+}
+
+src_test() {
+	#If someone wants to guarantee that emake will not make
+	#tests fail promiscuosly, please do, otherwise we're using make.
+	make check &> "${WORKDIR}"/check
+}
+
+src_install() {
+	base_src_install
+	dodoc ChangeLog README
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+}
diff --git a/x11-misc/google-gadgets/metadata.xml b/x11-misc/google-gadgets/metadata.xml
index c021f86759dc..f50be0a84a01 100644
--- a/x11-misc/google-gadgets/metadata.xml
+++ b/x11-misc/google-gadgets/metadata.xml
@@ -6,4 +6,8 @@
 		<email>voyageur@gentoo.org</email>
 		<name>Bernard Cafarelli</name>
 	</maintainer>
+	<use>
+		<flag name="soup">Enables XML HTTP request extension based on <pkg>net-libs/libsoup</pkg></flag>
+		<flag name="webkit">Enables browser element and script runtime based on <pkg>net-libs/webkit-gtk</pkg></flag>
+	</use>
 </pkgmetadata>