1 files changed, 67 insertions, 0 deletions
diff --git a/app-crypt/seahorse/seahorse-3.12.2.ebuild b/app-crypt/seahorse/seahorse-3.12.2.ebuild
new file mode 100644
index 000000000000..3a7f21d39d48
--- /dev/null
+++ b/app-crypt/seahorse/seahorse-3.12.2.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/seahorse/seahorse-3.12.2.ebuild,v 1.1 2014/05/31 08:19:51 pacho Exp $
+
+EAPI="5"
+GCONF_DEBUG="yes"
+
+inherit gnome2
+
+DESCRIPTION="A GNOME application for managing encryption keys"
+HOMEPAGE="https://wiki.gnome.org/Apps/Seahorse"
+
+LICENSE="GPL-2+ FDL-1.1+"
+SLOT="0"
+IUSE="avahi debug ldap"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+
+COMMON_DEPEND="
+	>=app-crypt/gcr-3.11.91:=
+	>=dev-libs/glib-2.10:2
+	>=x11-libs/gtk+-3.4:3
+	>=app-crypt/libsecret-0.16
+	>=net-libs/libsoup-2.33.92:2.4
+	x11-misc/shared-mime-info
+
+	net-misc/openssh
+	>=app-crypt/gpgme-1
+	|| (
+		=app-crypt/gnupg-2.0*
+		=app-crypt/gnupg-1.4* )
+
+	avahi? ( >=net-dns/avahi-0.6:= )
+	ldap? ( net-nds/openldap:= )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.35
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+# Need seahorse-plugins git snapshot
+RDEPEND="${COMMON_DEPEND}
+	!<app-crypt/seahorse-plugins-2.91.0_pre20110114
+"
+
+src_prepare() {
+	# FIXME: Do not mess with CFLAGS with USE="debug"
+	sed -e '/CFLAGS="$CFLAGS -g/d' \
+		-e '/CFLAGS="$CFLAGS -O0/d' \
+		-i configure.ac configure || die "sed 1 failed"
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# bindir is needed due to bad macro expansion in desktop file, bug #508610
+	gnome2_src_configure \
+		--bindir=/usr/bin \
+		--enable-pgp \
+		--enable-ssh \
+		--enable-pkcs11 \
+		--enable-hkp \
+		$(use_enable avahi sharing) \
+		$(use_enable debug) \
+		$(use_enable ldap) \
+		ITSTOOL=$(type -P true) \
+		VALAC=$(type -P true)
+}