blob: d75b3d06b7ed8b887128e2648bca7537f3338d78 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
|
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-qt/qtgui/qtgui-5.2.1.ebuild,v 1.1 2014/04/23 07:07:38 patrick Exp $
EAPI=5
QT5_MODULE="qtbase"
inherit qt5-build
DESCRIPTION="The Qt toolkit is a comprehensive C++ application development framework"
if [[ ${QT5_BUILD_TYPE} == live ]]; then
KEYWORDS=""
else
KEYWORDS="~amd64"
fi
# TODO: directfb, linuxfb, offscreen
IUSE="accessibility eglfs evdev gif gles2 +glib harfbuzz ibus jpeg kms opengl +png udev +xcb"
REQUIRED_USE="
eglfs? ( evdev gles2 )
gles2? ( opengl )
kms? ( evdev gles2 )
"
RDEPEND="
~dev-qt/qtcore-${PV}[debug=,glib=]
media-libs/fontconfig
media-libs/freetype:2
sys-libs/zlib
gif? ( media-libs/giflib )
gles2? ( || (
media-libs/mesa[egl,gles2]
media-libs/mesa[egl,gles]
) )
glib? ( dev-libs/glib:2 )
harfbuzz? ( >=media-libs/harfbuzz-0.9.12:0= )
ibus? ( ~dev-qt/qtdbus-${PV}[debug=] )
jpeg? ( virtual/jpeg:0 )
kms? (
media-libs/mesa[gbm]
virtual/udev
x11-libs/libdrm
)
opengl? ( virtual/opengl )
png? ( media-libs/libpng:0= )
udev? ( virtual/udev )
xcb? (
x11-libs/libICE
x11-libs/libSM
>=x11-libs/libX11-1.5
>=x11-libs/libXi-1.6
x11-libs/libXrender
>=x11-libs/libxcb-1.10[xkb]
>=x11-libs/libxkbcommon-0.2.0
x11-libs/xcb-util-image
x11-libs/xcb-util-keysyms
x11-libs/xcb-util-renderutil
x11-libs/xcb-util-wm
accessibility? ( ~dev-qt/qtdbus-${PV}[debug=] )
)
"
DEPEND="${RDEPEND}
evdev? ( sys-kernel/linux-headers )
test? ( ~dev-qt/qtnetwork-${PV}[debug=] )
"
PDEPEND="
ibus? ( app-i18n/ibus )
"
QT5_TARGET_SUBDIRS=(
src/gui
src/platformsupport
src/plugins/imageformats
src/plugins/platforminputcontexts/compose
src/plugins/platforms
)
pkg_setup() {
QCONFIG_ADD=(
$(use accessibility && echo accessibility-atspi-bridge)
$(usev eglfs)
$(usev evdev)
fontconfig
$(use gles2 && echo egl opengles2)
$(use harfbuzz && echo system-harfbuzz)
$(usev kms)
$(usev opengl)
$(use udev && echo libudev)
$(usev xcb)
)
QCONFIG_DEFINE=(
$(use accessibility && echo QT_ACCESSIBILITY_ATSPI_BRIDGE || echo QT_NO_ACCESSIBILITY_ATSPI_BRIDGE)
$(use eglfs || echo QT_NO_EGLFS)
$(use gles2 && echo QT_OPENGL_ES QT_OPENGL_ES_2 || echo QT_NO_EGL)
$(use jpeg || echo QT_NO_IMAGEFORMAT_JPEG)
$(use opengl || echo QT_NO_OPENGL)
$(use png || echo QT_NO_IMAGEFORMAT_PNG)
)
use ibus && QT5_TARGET_SUBDIRS+=(src/plugins/platforminputcontexts/ibus)
use opengl && QT5_TARGET_SUBDIRS+=(src/openglextensions)
qt5-build_pkg_setup
}
src_configure() {
local dbus="-no-dbus"
if use accessibility && use xcb; then
dbus="-dbus"
fi
local gl="-no-egl -no-opengl"
if use gles2; then
gl="-egl -opengl es2"
elif use opengl; then
gl="-no-egl -opengl desktop"
fi
local myconf=(
${dbus}
$(qt_use eglfs)
$(qt_use evdev)
-fontconfig
-system-freetype
$(use gif || echo -no-gif)
${gl}
$(qt_use glib)
$(qt_use harfbuzz harfbuzz system)
$(qt_use jpeg libjpeg system)
$(qt_use kms)
$(qt_use png libpng system)
$(use udev || echo -no-libudev)
$(use xcb && echo -xcb -xrender -sm)
)
qt5-build_src_configure
}
|