games-arcade/opensonic/opensonic-0.1.4-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-arcade/opensonic/opensonic-0.1.4-r1.ebuild,v 1.1 2012/05/17 00:42:37 hasufell Exp $

EAPI=3

inherit cmake-utils eutils games

MY_PN=opensnc
MY_P=${MY_PN}-src-${PV}

DESCRIPTION="A free open-source game based on the Sonic the Hedgehog universe"
HOMEPAGE="http://opensnc.sourceforge.net/"
SRC_URI="${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""
RESTRICT="fetch" # unsure about legality of graphics

DEPEND="media-libs/allegro:0[X,jpeg,png,vorbis]
	media-libs/libogg
	media-libs/libpng:0
	media-libs/libvorbis
	sys-libs/zlib
	virtual/jpeg"

S=${WORKDIR}/${MY_P}

pkg_nofetch() {
	einfo "Please download ${SRC_URI} from:"
	einfo "http://sourceforge.net/projects/opensnc/files/Open%20Sonic/0.1.4/"
	einfo "and move it to ${DISTDIR}"
	echo
}

src_prepare() {
	epatch "${FILESDIR}"/${PF}-cmake.patch
}

src_configure() {
	local mycmakeargs=(
		-DGAME_INSTALL_DIR="${GAMES_DATADIR}"/${PN}
		-DGAME_FINAL_DIR="${GAMES_BINDIR}"
		-DGAME_LIBDIR="$(games_get_libdir)/${PN}"
	)

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	for i in $(ls "${D}${GAMES_DATADIR}/${PN}") ; do
		dosym "${GAMES_DATADIR}/${PN}/${i}" \
			"$(games_get_libdir)/${PN}/${i}" || die
	done
	prepgamesdirs
}