media-sound/amarok-utils/amarok-utils-2.2.1.90.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok-utils/amarok-utils-2.2.1.90.ebuild,v 1.1 2009/12/16 00:40:09 tampakrap Exp $

EAPI="2"

if [[ ${PV} = *9999* ]]; then
	GIT_ECLASS="git"
	EGIT_PROJECT="amarok"
	EGIT_REPO_URI="git://gitorious.org/amarok/amarok.git"
fi

inherit base cmake-utils ${GIT_ECLASS}

MY_PN="amarok"

DESCRIPTION="Various utility programs for Amarok."
HOMEPAGE="http://amarok.kde.org/"
if [[ ${PV} = *9999* ]]; then
	SRC_URI=""
else
	SRC_URI="mirror://kde/unstable/${MY_PN}/${PV}/src/${MY_PN}-${PV}.tar.bz2"
fi

LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
SLOT="4"
IUSE="bindist debug"

DEPEND="
	>=media-libs/taglib-extras-1.0.1
	>=x11-libs/qt-core-4.4:4
	>=x11-libs/qt-dbus-4.4:4
	bindist? ( >=media-libs/taglib-1.6.1[-asf,-mp4] )
	!bindist? ( >=media-libs/taglib-1.6.1[asf,mp4] )
"
RDEPEND="${DEPEND}
	!<media-sound/amarok-2.1.80:2
	!<media-sound/amarok-2.1.80:${SLOT}
"

S="${WORKDIR}/${MY_PN}-${PV}"

DOCS="TODO README ChangeLog AUTHORS"

src_prepare() {
	# Disable po processing
	sed -e "s:include(MacroOptionalAddSubdirectory)::" \
		-i "${S}/CMakeLists.txt" \
		|| die "Removing include of MacroOptionalAddSubdirectory failed."
	sed -e "s:macro_optional_add_subdirectory( po )::" \
		-i "${S}/CMakeLists.txt" \
		|| die "Removing include of MacroOptionalAddSubdirectory failed."

	base_src_prepare
}

src_configure() {
	mycmakeargs=(
		-DWITH_PLAYER=OFF
		-DWITH_UTILITIES=ON
	)

	cmake-utils_src_configure
}