media-sound/orpheus/orpheus-1.6-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/orpheus/orpheus-1.6-r1.ebuild,v 1.3 2007/11/08 17:00:22 armin76 Exp $

WANT_AUTOCONF=2.5
WANT_AUTOMAKE=1.8

inherit eutils autotools

DESCRIPTION="Command line MP3 player."
HOMEPAGE="http://konst.org.ua/en/orpheus"
SRC_URI="http://konst.org.ua/download/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="alpha amd64 ~ppc sparc x86"
IUSE="cddb"

DEPEND=">=sys-libs/ncurses-5.2
	>=media-libs/libvorbis-1.0_beta1
	virtual/mpg123
	cddb? ( gnome-base/libghttp )
	media-sound/vorbis-tools"

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}/1.5-amd64.patch"

	# Fix a stack-based buffer overflow in kkstrtext.h in ktools library.
	# Bug 113683, CVE-2005-3863.
	epatch "${FILESDIR}"/101_fix-buffer-overflow.diff

	# configures generated by different autoconf versions
	# cause problems when calling econf
	cd "${S}/kkstrtext-0.1"
	eautoreconf
	cd "${S}/kkconsui-0.1"
	eautoreconf

	# force not using deprecated libghttp
	cd "${S}"
	use cddb || epatch "${FILESDIR}/${P}-nolibghttp.patch"
}

src_compile() {
	econf || die "configure failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"
	dodoc AUTHORS ChangeLog NEWS README TODO
}