blob: bccdded35111674d2cc0c58c32a76bb3e1e74d8b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-9-r3.ebuild,v 1.3 2012/07/22 17:24:06 armin76 Exp $
EAPI=4
EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/kernel/${PN}/${PN}.git"
[[ ${PV} == 9999 ]] && vcs=git-2
inherit ${vcs} autotools eutils toolchain-funcs libtool
unset vcs
if [[ ${PV} != 9999 ]] ; then
SRC_URI="mirror://kernel/linux/utils/kernel/kmod/${P}.tar.xz"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
fi
DESCRIPTION="library and tools for managing linux kernel modules"
HOMEPAGE="http://git.kernel.org/?p=utils/kernel/kmod/kmod.git"
LICENSE="LGPL-2"
SLOT="0"
IUSE="debug doc lzma static-libs +tools zlib"
RDEPEND="!sys-apps/module-init-tools
!sys-apps/modutils
lzma? ( app-arch/xz-utils )
zlib? ( >=sys-libs/zlib-1.2.6 )" #427130
DEPEND="${RDEPEND}
doc? ( dev-util/gtk-doc )
lzma? ( virtual/pkgconfig )
zlib? ( virtual/pkgconfig )"
# Upstream does not support running the test suite with custom configure flags.
# I was also told that the test suite is intended for kmod developers.
# So we have to restrict it.
# See bug #408915.
RESTRICT="test"
src_prepare()
{
if [ ! -e configure ]; then
if use doc; then
gtkdocize --copy --docdir libkmod/docs || die
else
touch libkmod/docs/gtk-doc.make
fi
eautoreconf
else
elibtoolize
fi
}
src_configure()
{
econf \
$(use_enable static-libs static) \
$(use_enable tools) \
$(use_enable debug) \
$(use_enable doc gtk-doc) \
$(use_with lzma xz) \
$(use_with zlib)
}
src_install()
{
default
find "${D}" -name libkmod.la -exec rm -f {} +
if use tools; then
local cmd
for cmd in insmod lsmod modinfo rmmod; do
dosym kmod /usr/bin/${cmd}
done
# according to upstream, modprobe can be called directly by the kernel,
# so it cannot be moved to /usr/bin at this time.
dosym /usr/bin/kmod /sbin/modprobe
# another hardcoded path in the Linux source tree, bug #426698
dosym /usr/bin/kmod /sbin/depmod
fi
}
|
GitWeb