sys-apps/usb_modeswitch/usb_modeswitch-1.1.9.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/usb_modeswitch/usb_modeswitch-1.1.9.ebuild,v 1.1 2011/08/12 09:59:02 hanno Exp $

EAPI="4"
inherit multilib toolchain-funcs

MY_PN="${PN/_/-}"
MY_P="${MY_PN}-${PV}"
DATA_VER="20110805"

DESCRIPTION="USB_ModeSwitch is a tool for controlling 'flip flop' (multiple devices) USB gear like UMTS sticks"
HOMEPAGE="http://www.draisberghof.de/usb_modeswitch/"
SRC_URI="http://www.draisberghof.de/${PN}/${MY_P}.tar.bz2
	http://www.draisberghof.de/${PN}/${MY_PN}-data-${DATA_VER}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND="virtual/libusb:0"
RDEPEND="${DEPEND}
	dev-lang/tcl" # usb_modeswitch script is tcl

S="${WORKDIR}/${MY_P}"

src_prepare() {
	sed -i -e 's/-s //' Makefile || die 'sed failed.'
}

src_compile() {
	emake CC="$(tc-getCC)"
}

src_install() {
	local udevdir="${D}/$(get_libdir)/udev"
	emake DESTDIR="${D}" UDEVDIR="${udevdir}" install

	cd ../"${MY_PN}-data-${DATA_VER}"
	emake DESTDIR="${D}" RULESDIR="${udevdir}/rules.d" files-install db-install
}