blob: a6c9beb2ed9c4d09a50cedefc3d9f42764c63d3e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/qscintilla/qscintilla-2.4.2.ebuild,v 1.1 2010/01/21 21:14:38 hwoarang Exp $
EAPI="2"
inherit qt4-r2
MY_P="QScintilla-gpl-${PV/_pre/-snapshot-}"
DESCRIPTION="A Qt port of Neil Hodgson's Scintilla C++ editor class"
HOMEPAGE="http://www.riverbankcomputing.co.uk/software/qscintilla/intro"
SRC_URI="http://www.riverbankcomputing.co.uk/static/Downloads/QScintilla2/${MY_P}.tar.gz"
LICENSE="|| ( GPL-2 GPL-3 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="doc python"
DEPEND="x11-libs/qt-gui:4"
RDEPEND="${DEPEND}"
PDEPEND="python? ( ~dev-python/qscintilla-python-${PV} )"
S="${WORKDIR}"/${MY_P}
PATCHES=( "${FILESDIR}/${PN}-2.4-designer.patch" )
src_configure() {
cd "${S}"/Qt4
einfo "Configuring qscintilla"
eqmake4 qscintilla.pro
cd "${S}"/designer-Qt4
einfo "Configuring designer plugin"
eqmake4 designer.pro
}
src_compile() {
cd "${S}"/Qt4
einfo "Building qscintilla"
emake all staticlib || die "emake failed"
cd "${S}"/designer-Qt4
einfo "Building designer plugin"
emake || die "failed to build designer plugin"
}
src_install() {
cd "${S}"/Qt4
# header files
insinto /usr/include/Qsci
doins Qsci/*.h || die
# libraries
dolib.so libqscintilla2.so* || die
dolib.a libqscintilla2.a || die
# translations
insinto /usr/share/${PN}/translations
for trans in qscintilla_*.qm; do
doins ${trans} || die
dosym /usr/share/${PN}/translations/${trans} \
/usr/share/qt4/translations/${trans} || die
done
# designer plugin
cd "${S}"/designer-Qt4
emake INSTALL_ROOT="${D}" install || die "designer plugin installation failed"
# documentation
cd "${S}"
dodoc ChangeLog NEWS
if use doc; then
dohtml doc/html-Qt4/* || die
insinto /usr/share/doc/${PF}/Scintilla
doins doc/Scintilla/* || die
fi
}
pkg_postinst() {
ewarn "Please remerge dev-python/PyQt4 if you have problems with eric or other"
ewarn "qscintilla related packages before submitting bug reports."
}
|
GitWeb