dev-util/sysprof: bump to 3.26.1

Package-Manager: Portage-2.3.43, Repoman-2.3.10

2 files changed, 64 insertions, 0 deletions

diff --git a/dev-util/sysprof/Manifest b/dev-util/sysprof/Manifest
index 048dac70a652..684b0f5ef58c 100644
--- a/dev-util/sysprof/Manifest
+++ b/dev-util/sysprof/Manifest
@@ -1 +1,2 @@
 DIST sysprof-3.24.1.tar.xz 595920 BLAKE2B 90582eab3fc12a0169c151ce0fad20b839841f77a31e5858f8d660f9b0f2630396bec3b239dd88baa3f6e3dd936bdd6d63a652e491a1d32f966a755f9099f160 SHA512 5d323bcb9923c511065132711963dc8856c4d837b4d7ccfae5cc5794be5ac8ad1dc42504025469199f4bfd6a6fad4d8f49b7b21cab6f0c9a954820182e75c7d0
+DIST sysprof-3.26.1.tar.xz 609076 BLAKE2B fd10ce27b224100558ff5bb9c75cfffcb76b2331d2c4056bd73a9ace1ea155e61d705240acf6fefa805fba2333f6d439369d5b1cc16e0c537ab9fed408bf6d85 SHA512 ee03360e4971cd91129bac3cc9d2cf292d29aafe1cdacd078e404ee15c3ff02bcd0c0159502605c00eb2abd3a46917cf70458ad05e48b594eeb2835ead55c34c
diff --git a/dev-util/sysprof/sysprof-3.26.1.ebuild b/dev-util/sysprof/sysprof-3.26.1.ebuild
new file mode 100644
index 000000000000..144b2c9fcadc
--- /dev/null
+++ b/dev-util/sysprof/sysprof-3.26.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome2 linux-info systemd
+
+DESCRIPTION="System-wide Linux Profiler"
+HOMEPAGE="http://sysprof.com/"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug gtk systemd"
+
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	gtk? (
+		sys-auth/polkit
+		>=x11-libs/gtk+-3.22.0:3 )
+	systemd? (
+		sys-auth/polkit
+		>=sys-apps/systemd-222 )
+"
+DEPEND="${RDEPEND}
+	app-text/yelp-tools
+	>=sys-devel/gettext-0.19.6
+	>=sys-kernel/linux-headers-2.6.32
+	dev-libs/appstream-glib
+	virtual/pkgconfig
+"
+
+pkg_pretend() {
+	kernel_is -ge 2 6 31 && return
+	die "Sysprof will not work with a kernel version less than 2.6.31"
+}
+
+src_configure() {
+	# introspection & vala not use in build system
+	# --with-sysprofd=host currently unavailable from ebuild
+	gnome2_src_configure \
+		$(use_enable debug) \
+		$(use_enable gtk) \
+		--disable-introspection \
+		--disable-static \
+		--disable-vala \
+		--with-sysprofd=$(usex systemd bundled no) \
+		--with-systemdsystemunitdir=$(systemd_get_systemunitdir)
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	elog "On many systems, especially amd64, it is typical that with a modern"
+	elog "toolchain -fomit-frame-pointer for gcc is the default, because"
+	elog "debugging is still possible thanks to gcc4/gdb location list feature."
+	elog "However sysprof is not able to construct call trees if frame pointers"
+	elog "are not present. Therefore -fno-omit-frame-pointer CFLAGS is suggested"
+	elog "for the libraries and applications involved in the profiling. That"
+	elog "means a CPU register is used for the frame pointer instead of other"
+	elog "purposes, which means a very minimal performance loss when there is"
+	elog "register pressure."
+}