media-video/jellyfin-media-player: new package, add 1.11.1

Signed-off-by: John M. Harris Jr. <johnmh@johnmh.me>

2 files changed, 71 insertions, 0 deletions

diff --git a/media-video/jellyfin-media-player/Manifest b/media-video/jellyfin-media-player/Manifest
new file mode 100644
index 0000000..7815e6d
--- /dev/null
+++ b/media-video/jellyfin-media-player/Manifest
@@ -0,0 +1,2 @@
+DIST jellyfin-media-player-1.11.1.gh.tar.gz 514141 BLAKE2B 00984b9241613a94ab0c27f21c4202ca064ff42cba8ba3d01b7bda20af53e80aa4ce14df9a8e906574d94fb3146a68cc84bc61e2be94d4e16ce087c97494de5b SHA512 24616c36e92e168655f6c37ef214ad7aa46df1cb331e1bff225b83b83da18fa91fb66d13145744c20cf49d2b92132cff065f6e8429bc111fd1be1a3d68a9c8ec
+EBUILD jellyfin-media-player-1.11.1.ebuild 1455 BLAKE2B dc8cf9dc128c45aa000daa269334eeef291735e057758a6b9b4dedcc6c6f5209e86e908a3e682d18ee2926b60d37afbc6a3f7da56452b9fa62583261ed05085a SHA512 cfbd57f6d4ff0bc9e84fd63220a10431a4344132075c2b3c6d6ff7a0c0a975a6601785190d5f1eb4cab761a951eb920a28b3fded0b5fa043a5b8d9b7caf1ec6c
diff --git a/media-video/jellyfin-media-player/jellyfin-media-player-1.11.1.ebuild b/media-video/jellyfin-media-player/jellyfin-media-player-1.11.1.ebuild
new file mode 100644
index 0000000..f47a21e
--- /dev/null
+++ b/media-video/jellyfin-media-player/jellyfin-media-player-1.11.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit cmake python-any-r1
+
+DESCRIPTION="Jellyfin Desktop Client based on Plex Media Player"
+HOMEPAGE="https://github.com/jellyfin/jellyfin-media-player"
+
+SRC_URI="
+	https://github.com/jellyfin/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+
+KEYWORDS="~amd64"
+IUSE="+dbus"
+
+DEPEND="
+	dev-libs/libcec
+	dev-qt/qtcore:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtquickcontrols:5
+	dev-qt/qtwebchannel:5
+	dev-qt/qtwebengine:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	media-libs/libsdl2
+	media-video/mpv:=[libmpv]
+	sys-libs/zlib
+	virtual/opengl
+	x11-libs/libX11
+	x11-libs/libXrandr
+	dbus? ( dev-qt/qtdbus:5 )
+"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+"
+
+# x11-misc/xdg-utils is used for xdg-screensaver, which is used to inhibit
+# screen locking
+
+RDEPEND="
+	${DEPEND}
+	media-video/jellyfin-web-bin
+	!dbus? ( x11-misc/xdg-utils )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DOpenGL_GL_PREFERENCE=GLVND
+		# PMP, at least prior to the fork into JMP, used to download codecs,
+		# for safe measure, disable that.
+		-DENABLE_CODECS=OFF
+		# LINUX_X11POWER instructs JMP to use xdg-screensaver instead of dbus
+		# for inhibiting screen saving.
+		-DLINUX_X11POWER="$(usex dbus OFF ON)"
+	)
+	cmake_src_configure
+}