Use install functions from elisp-common.eclass instead of make install, in order to avoid double byte-compilation of elisp files. Update to EAPI 5. Specify LICENSE more precisely. Use readme.gentoo.eclass instead of elog for message display.

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 9433907D693FB5B8!)

1 files changed, 43 insertions, 0 deletions

diff --git a/app-emacs/zenirc/zenirc-2.112-r1.ebuild b/app-emacs/zenirc/zenirc-2.112-r1.ebuild
new file mode 100644
index 000000000000..8fed426afb14
--- /dev/null
+++ b/app-emacs/zenirc/zenirc-2.112-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emacs/zenirc/zenirc-2.112-r1.ebuild,v 1.1 2014/02/10 17:00:43 ulm Exp $
+
+EAPI=5
+
+inherit readme.gentoo elisp
+
+DESCRIPTION="A full-featured scriptable IRC client for the Emacs text editor"
+HOMEPAGE="http://www.zenirc.org/"
+SRC_URI="ftp://ftp.zenirc.org/pub/zenirc/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+SITEFILE="50${PN}-gentoo.el"
+
+src_configure() {
+	# econf won't work because of unknown options
+	./configure --prefix="${EPREFIX}/usr/" || die "configure failed"
+}
+
+src_compile() {
+	default
+}
+
+src_install() {
+	elisp-install ${PN} src/*.el src/*.elc
+	elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+
+	doinfo doc/zenirc.info
+	dodoc BUGS INSTALL NEWS README TODO
+
+	cd doc
+	docinto doc
+	dodoc 666.conspiracy FAQ README-OLD ctcp.doc irc-operators \
+		server-list tao-of-irc tour.of.irc undernet
+
+	DOC_CONTENTS="Refer to the Info documentation and
+		${SITELISP}/${PN}/zenirc-example.el for customization hints."
+	readme.gentoo_create_doc
+}