Bump to bobotpp-2.2.3 and to EAPI=4.

(Portage version: 2.2.0_alpha37-r1/cvs/Linux x86_64)

1 files changed, 54 insertions, 0 deletions

diff --git a/net-irc/bobotpp/bobotpp-2.2.3.ebuild b/net-irc/bobotpp/bobotpp-2.2.3.ebuild
new file mode 100644
index 000000000000..0f733b60bd4e
--- /dev/null
+++ b/net-irc/bobotpp/bobotpp-2.2.3.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-irc/bobotpp/bobotpp-2.2.3.ebuild,v 1.1 2011/06/15 04:06:52 binki Exp $
+
+EAPI=4
+
+inherit autotools autotools-utils eutils
+
+DESCRIPTION="A flexible IRC bot scriptable in scheme"
+HOMEPAGE="http://unknownlamer.org/code/bobot.html"
+SRC_URI="http://savannah.nongnu.org/download/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="guile"
+
+DEPEND="guile? ( dev-scheme/guile )"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.2.2-asneeded.patch \
+		"${FILESDIR}"/${P}-stdout.patch
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-crypt
+		$(use_enable guile scripting)
+	)
+
+	autotools-utils_src_configure
+}
+
+src_install() {
+	autotools-utils_src_install
+
+	dosym bobot++.info /usr/share/info/bobotpp.info
+
+	dodoc AUTHORS ChangeLog NEWS README TODO
+	dohtml documentation/index.html
+
+	docinto examples/config
+	dodoc examples/config/*
+
+	docinto examples/scripts
+	dodoc examples/scripts/*
+}
+
+pkg_postinst() {
+	elog "You can find a sample configuration file set in"
+	elog "${EPREFIX}/usr/share/doc/${PF}/example-config"
+}