sys-block/mpt-status/mpt-status-1.2.0-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-block/mpt-status/mpt-status-1.2.0-r1.ebuild,v 1.1 2014/06/05 13:10:13 pinkbyte Exp $

EAPI=5

inherit eutils toolchain-funcs

DESCRIPTION="Query tool to access the running configuration and status of LSI SCSI HBAs"
HOMEPAGE="http://www.drugphish.ch/~ratz/mpt-status/"
SRC_URI="http://www.drugphish.ch/~ratz/mpt-status/${P}.tar.bz2
	mirror://gentoo/${PN}-1.2.0-linux-sources.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"

src_prepare() {
	epatch "${FILESDIR}/${PN}-1.2.0-gentoo.patch"

	sed -i -e 's,\(^.*linux/compiler\.h.*$\),,' mpt-status.h || die
	sed -i -e '/KERNEL_PATH/d' Makefile || die

	epatch_user
}

src_compile() {
	emake CC="$(tc-getCC)"
}

src_install() {
	emake DESTDIR="${D}" install
	dodoc doc/{AUTHORS,Changelog,DeveloperNotes,FAQ,README,ReleaseNotes,THANKS,TODO}
}